From ee8e4d3a1824b6e022e20df6da621d8db817e90b Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Wed, 16 Mar 2022 23:36:50 +0200
Subject: [PATCH] app-editors/gnome-text-editor: New default text editor for
 GNOME 42

Bug: https://bugs.gentoo.org/835448
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 app-editors/gnome-text-editor/Manifest        |  1 +
 .../gnome-text-editor-42_rc1.ebuild           | 56 +++++++++++++++++++
 app-editors/gnome-text-editor/metadata.xml    |  8 +++
 profiles/package.mask                         |  1 +
 4 files changed, 66 insertions(+)
 create mode 100644 app-editors/gnome-text-editor/Manifest
 create mode 100644 app-editors/gnome-text-editor/gnome-text-editor-42_rc1.ebuild
 create mode 100644 app-editors/gnome-text-editor/metadata.xml

diff --git a/app-editors/gnome-text-editor/Manifest b/app-editors/gnome-text-editor/Manifest
new file mode 100644
index 0000000000000..fbd784b9c79e2
--- /dev/null
+++ b/app-editors/gnome-text-editor/Manifest
@@ -0,0 +1 @@
+DIST gnome-text-editor-42.rc1.tar.xz 1093060 BLAKE2B 14bddc82e4dd410b357cff7274ed35c07b13da7648db5840eb2c8dae7c057935b9b6f5f249c8c04f3a8ed27543014de8f7fc38b98985cd481064752f28a0b623 SHA512 debebccceb4bbe2bfc87a1c1f0813b10fc0c565cc89c6b3a826daa0a3344c88b9f20135087335f61d7b736a8c8ada7e2f823795c1e6c8d3d03ac7325afd0a9ae
diff --git a/app-editors/gnome-text-editor/gnome-text-editor-42_rc1.ebuild b/app-editors/gnome-text-editor/gnome-text-editor-42_rc1.ebuild
new file mode 100644
index 0000000000000..7f7de71f724e1
--- /dev/null
+++ b/app-editors/gnome-text-editor/gnome-text-editor-42_rc1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="A simple text editor for the GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-text-editor"
+SRC_URI="mirror://gnome/sources/gnome-text-editor/42/gnome-text-editor-${PV/_/.}.tar.xz"
+S="${WORKDIR}/gnome-text-editor-${PV/_/.}"
+
+LICENSE="GPL-3+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="spell"
+
+KEYWORDS="~amd64"
+
+DEPEND="
+	>=dev-libs/glib-2.69:2
+	>=gui-libs/gtk-4.6:4
+	>=gui-libs/gtksourceview-5.3.1:5
+	gui-libs/libadwaita:1
+	dev-libs/libpcre
+	spell? (
+		>=app-text/enchant-2.2.0:2
+		dev-libs/icu:=
+	)
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.21
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature spell enchant)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/app-editors/gnome-text-editor/metadata.xml b/app-editors/gnome-text-editor/metadata.xml
new file mode 100644
index 0000000000000..7b343b06be8a9
--- /dev/null
+++ b/app-editors/gnome-text-editor/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+</pkgmetadata>
diff --git a/profiles/package.mask b/profiles/package.mask
index 1d331ecb372c8..cff46aa39631b 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -411,6 +411,7 @@ app-misc/emelfm2
 # GNOME 42 mask, bug #835448
 >=gui-libs/libhandy-1.5.0
 >=gui-libs/gtksourceview-5.3
+>=app-editors/gnome-text-editor-42_alpha
 
 # Michał Górny <mgorny@gentoo.org> (2021-12-18)
 # EOL kernel with known vulnerabilities.  Please move to one of the LTS