From ee4e8843c8318d019d72f7205debd912656fb42d Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Sat, 28 Jun 2025 12:43:38 +0700
Subject: [PATCH] dev-util/diffuse: bump to 0.10.0

Signed-off-by: Andrey Grozin <grozin@gentoo.org>
---
 dev-util/diffuse/Manifest              |  1 +
 dev-util/diffuse/diffuse-0.10.0.ebuild | 50 ++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 dev-util/diffuse/diffuse-0.10.0.ebuild

diff --git a/dev-util/diffuse/Manifest b/dev-util/diffuse/Manifest
index dee4c3279bcdc..76e064bab43f6 100644
--- a/dev-util/diffuse/Manifest
+++ b/dev-util/diffuse/Manifest
@@ -1 +1,2 @@
+DIST diffuse-0.10.0.tar.gz 1195918 BLAKE2B dfdf98c063ea94f851bf593a40d500a448afd06ee2eb6c7826e4ae16900c9ea327f41369cbb33a5cee7224f4428e43f4a8ce88ba3a44fbb36d6b880161670091 SHA512 7ac19f52cb5907069286275d610ff8656f5559ebc9935e03ae25b56c19682c90534373a50528bdc8c6912baa1c1fa6b5de5ab4d85451f29a841bf2039c5a627d
 DIST diffuse-0.9.0.tar.gz 1193105 BLAKE2B 934d38722e0bd9f83a915c681521c1699e0a2efefdcbbb3e23c3f9635467fb31d9f364a72b0e7c78ca65bf9fe154e5ebbeecdbfe1a4b412149a3b0f3a511d6e9 SHA512 9a9ed6047531eaf80fed867bc2feba081f183ee7e5e5c940b0cb912af6d17c7c22df48b7aa76c3f17d4fafeff1bade45216d26ef689fef33b3680bdc70ed80ac
diff --git a/dev-util/diffuse/diffuse-0.10.0.ebuild b/dev-util/diffuse/diffuse-0.10.0.ebuild
new file mode 100644
index 0000000000000..3d6fe485a000a
--- /dev/null
+++ b/dev-util/diffuse/diffuse-0.10.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..13} )
+PLOCALES="cs de es fr it ja ka ko nl pl pt pt_BR ru sv th tr zh_CN zh_TW"
+inherit meson plocale python-r1 xdg
+
+DESCRIPTION="A graphical tool to compare and merge text files"
+HOMEPAGE="http://diffuse.sourceforge.net/ https://github.com/MightyCreak/diffuse/"
+SRC_URI="https://github.com/MightyCreak/diffuse/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_USEDEP},cairo]
+	')
+	x11-libs/gtk+:3[introspection]
+	!sci-chemistry/tinker"
+# file collision, bug #279018
+
+src_prepare() {
+	default
+	plocale_find_changes po '' '.po'
+
+	rm_locale() {
+		rm -f po/${1}.po
+		rm -rf data/usr/share/man/${1}
+		rm -rf data/usr/share/gnome/help/${PN}/$1
+		rm -f data/usr/share/omf/${PN}/${PN}-$1.omf
+		sed -e "/^${1}/d" -i po/LINGUAS
+	}
+
+	plocale_for_each_disabled_locale rm_locale
+}
+
+src_install() {
+	meson_src_install
+	rm "${D}"/usr/bin/${PN} || die "rm ${PN} failed"
+	python_foreach_impl python_doscript ../${P}-build/src/${PN}/${PN}
+	mkdir "${D}"/usr/share/metainfo || die "mkdir metainfo failed"
+	mv "${D}"/usr/share/appdata/* "${D}"/usr/share/metainfo/ \
+		|| die "mv appdata -> metainfo failed"
+	dodoc AUTHORS CHANGELOG.md README.md
+}