diff --git a/dev-python/pluginbase/Manifest b/dev-python/pluginbase/Manifest
new file mode 100644
index 0000000000000..a1931863fdfa6
--- /dev/null
+++ b/dev-python/pluginbase/Manifest
@@ -0,0 +1 @@
+DIST pluginbase-0.5.tar.gz 41964 SHA256 b4f830242a078a4f44c978a84f3365bba4d008fdd71a591c71447f4df35354dd SHA512 921ddc7dacb6ad63abc90beb1d1d993e7b15c9cfe21e850a5852eb40735436e08b39fd2a6d83e23f641014ee81e718aca147ef1e21b55f94ce04a64ba7780455 WHIRLPOOL c15e58b029c101aea683df671fd7e58bcfa8635a21ca0a5867ac04114b1b9855a1ba4eac590231b408ac69c0f9bf4ef3c0bb3248797e762550af5e6403bf9593
diff --git a/dev-python/pluginbase/metadata.xml b/dev-python/pluginbase/metadata.xml
new file mode 100644
index 0000000000000..0610970f98a57
--- /dev/null
+++ b/dev-python/pluginbase/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">pluginbase</remote-id>
+    <remote-id type="github">mitsuhijo/pluginbase</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/dev-python/pluginbase/pluginbase-0.5.ebuild b/dev-python/pluginbase/pluginbase-0.5.ebuild
new file mode 100644
index 0000000000000..8954509650f88
--- /dev/null
+++ b/dev-python/pluginbase/pluginbase-0.5.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Support library for building plugins sytems in Python"
+HOMEPAGE="https://github.com/mitsuhiko/pluginbase"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (	dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -e "s/, 'sphinx.ext.intersphinx'//" \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	cd tests && PYTHONPATH=.. py.test --tb=native || die "Tests fail with ${EPYTHON}"
+}