sci-mathematics/pspp: add 2.0.1

* Rename gtk use flag to gui.
https://projects.gentoo.org/qa/policy-guide/use-flags.html#pg0802

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/41839
Closes: https://github.com/gentoo/gentoo/pull/41839
Signed-off-by: Sam James <sam@gentoo.org>

sci-mathematics/pspp/Manifest

@@ -1 +1,2 @@
 DIST pspp-1.6.2.tar.gz 9249366 BLAKE2B d1a4fb352615be8d5f3af3125d10760648ab16e8d2b42dbf0632de64a5bb5bbe87b9b56661c7f600ea09c6a359e477376d3efb821280023d1825d6eb7b0a299f SHA512 fd8b6b23ae4e4a1a560bf4d20c35e761d84dcde2e220648303303f11e9c17d56285a3d5b3c26e7dad44d52ecc82fdf93fdc51a3533ff907f2ca1f1474922e31f
+DIST pspp-2.0.1.tar.gz 10943885 BLAKE2B 14fd946116e88f021078b8d2e8e26b657408c54e7af3c0877bdd3428c8ac80cd44bc24c667ce30fb20bd2ec6137be1bdcb7873294dc55879e353fa75b35ccdee SHA512 e9be8c46d5e46b3665d1efa0e8015a0c738ceef8cdd8f8dddc7288cc6522c66a1372f7ad7be42caafbe2b37a96c31b83c3a4ad0503bdb2f0b1e3261c33529b31

sci-mathematics/pspp/pspp-2.0.1.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit python-any-r1 xdg
+
+DESCRIPTION="Program for statistical analysis of sampled data"
+HOMEPAGE="https://www.gnu.org/software/pspp/pspp.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ FDL-1.3+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples gui ncurses nls perl postgres"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	>=sci-libs/gsl-1.13:0=
+	sys-libs/readline:0=
+	sys-libs/zlib
+	virtual/libiconv
+	x11-libs/cairo[svg(+)]
+	x11-libs/pango
+	gui? (
+		>=dev-libs/glib-2.44:2
+		>=x11-libs/gtk+-3.22.0:3
+		>=x11-libs/gtksourceview-4.0:4
+		>=x11-libs/spread-sheet-widget-0.7
+	)
+	postgres? ( dev-db/postgresql:=[server(+)] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( virtual/texi2dvi )
+	gui? ( dev-util/glib-utils )
+"
+
+pkg_pretend() {
+	ewarn "Starting with pspp-1.4.0 the pspp-mode emacs package is no longer"
+	ewarn "shipped with pspp itself, and should instead be fetched from ELPA:"
+	ewarn "https://elpa.gnu.org/packages/pspp-mode.html"
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_with gui) \
+		$(use_with perl perl-module) \
+		$(use_with postgres libpq)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake html pdf
+		HTML_DOCS=( doc/pspp{,-dev}.html )
+	fi
+}
+
+src_install() {
+	default
+
+	use doc && dodoc doc/pspp{,-dev}.pdf
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	find "${ED}" -name '*.la' -type f -delete || die
+}