dev-build/dolphin-plugins-makefileactions: 25.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-build/dolphin-plugins-makefileactions/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-25.08.3.tar.xz 336856 BLAKE2B 7714809fde0c00ba52c002c3ed6a12a2006a2a3cf980e211ff5c736ef2138e50acddc03f70ffc70030313cbaabf259de826129c0766354a389c27655cb164b9c SHA512 df887b3be57da1344f5311093ba13251c4af554f4f3d93b3e44c0835da21ac8cec0fccaaee7e8b8e9162e56b1396bcbbded2bc5f02955b30ba01203fff0a279a
+DIST dolphin-plugins-25.12.0.tar.xz 336404 BLAKE2B 6966e1f13617e25d7249088623f25330d5e7555ee6695611338ad675399b1b56a309ee854462cde866d417f7dc933749fc68f6953ec67c1c45a0a93f3f92cd76 SHA512 2441fa7da4b42cbb6016e420f8ec025141bb2ca63975c35baca33337f852d361d484a3b1d6a0dd1a575377b385056e91bf6bbfba692c81ef5207f4316d5091d4

dev-build/dolphin-plugins-makefileactions/dolphin-plugins-makefileactions-25.12.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="makefileactions"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.19.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Makefile targets integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	!<kde-apps/dolphin-plugins-subversion-24.08.2-r1
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# kcompletion, ktextwidgets only required by other plugins
+	ecm_punt_kf_module Completion
+	ecm_punt_kf_module TextWidgets
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}