From ecd293ef39b34e712368aefd68e60f21aa30d34a Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 6 Nov 2025 16:39:08 +0100
Subject: [PATCH] kde-apps/akonadi: 25.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/akonadi/Manifest               |  1 +
 kde-apps/akonadi/akonadi-25.08.3.ebuild | 66 +++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 kde-apps/akonadi/akonadi-25.08.3.ebuild

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index 4aaf34741027a..c8cb8454ffcb2 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1 +1,2 @@
 DIST akonadi-25.08.2.tar.xz 1766996 BLAKE2B bf73a266677bbea7a5ba9c7eedbbf6e60eb3e22dc3cd15427ed53dcc032eaa8918499ab52363c05a2ec401da5b070599a8c85f53d6c65a46f3a26af94f376439 SHA512 267a2709ba8709fd4249c7da022442ec99c5026996e491420de294b2222723ac2262945c9b74c9e7e8c43a7b1d7aa68c61dcd0cfd3cc876b437d457974721aba
+DIST akonadi-25.08.3.tar.xz 1767120 BLAKE2B 34570bc98b3a00a45bb0b0dbb130a9d40616d24b23e792db324bed3682c55f895e0bd2bc664fe00557324ee541cc7bc14b62c189eaa25c6e7e5307c47a59368c SHA512 cd142e4e0277e7c05907256e949c257aea435a7d210de6d39a844f18cb445bafefa16dfcd844b4c7d0ae4a1e188a2ae5aa91cc09e31269a61f6b7a7ad0247a28
diff --git a/kde-apps/akonadi/akonadi-25.08.3.ebuild b/kde-apps/akonadi/akonadi-25.08.3.ebuild
new file mode 100644
index 0000000000000..6bf9dba92bbae
--- /dev/null
+++ b/kde-apps/akonadi/akonadi-25.08.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_DESIGNERPLUGIN="true"
+ECM_QTHELP="true"
+ECM_TEST="forceoptional"
+KFMIN=6.16.0
+QTMIN=6.9.1
+VIRTUALDBUS_TEST="true"
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
+HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
+
+LICENSE="LGPL-2.1+"
+SLOT="6/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm64"
+IUSE="tools +webengine xml"
+
+REQUIRED_USE="test? ( tools )"
+
+# some akonadi tests time out, that probably needs more work as it's ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,sql,widgets,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	webengine? (
+		kde-apps/kaccounts-integration:6
+		>=net-libs/accounts-qt-1.17[qt6(+)]
+	)
+	xml? ( dev-libs/libxml2:= )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<app-office/merkuro-25.07.80
+	kde-apps/akonadi-config
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TOOLS=$(usex tools)
+		$(cmake_use_find_package webengine AccountsQt6)
+		$(cmake_use_find_package webengine KAccounts6)
+		$(cmake_use_find_package xml LibXml2)
+	)
+
+	ecm_src_configure
+}