xfce-base/thunar: Bump to 4.20.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar/Manifest

@@ -1,2 +1,3 @@
 DIST thunar-4.18.11.tar.bz2 2944418 BLAKE2B dc5182192d3c9de2330af0ef236f90939da2642b78f0676f07b73a794f51956be02d5be6bc2d7026e04d14f4c64753dbc8734e87e9e832a0921c24cab52d1bfa SHA512 1ed9dbcbf5f87fcbf61d89e023d89fef9ba436bbb698639367c94f5761e1f9f919c48599f19cd159044be8190a5cda5bfaf9da7701730b095c8d20243e4a7b3a
 DIST thunar-4.20.1.tar.bz2 4451310 BLAKE2B eb0693758130e8b404f0b57a00f5e1e30c1268fbce9d60f1ced271a875b0c489c27d360552a8c6211bddc42fb9b8a95edd5c79ac8420fb3173e9d7adcb5c0775 SHA512 89b9d59d7731af6ae43ebe5d29f8644e05b03db3db07170eeadf82eb2d783a2c46327d6cb44bb49d567f9b69116cfa09bc89cd4f69815d9fb5b09ac57173d84b
+DIST thunar-4.20.2.tar.bz2 4452492 BLAKE2B b75f78a494d608180b1f337eb272ca7a1df2f48b908b349633869e1241053edce689c803734b6845f36f13ba459749253d34649e9567803bb090722dbb388b46 SHA512 c023dc136d10f79f01482207be6f590fa352798bd6fc923910e513bb0774681ac027b2da9aaee4899cd096925225c2c079a5bb9561c0397a0fbc6c844261e214

xfce-base/thunar/thunar-4.20.2.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/thunar/start
+	https://gitlab.xfce.org/xfce/thunar/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="exif introspection libnotify pcre +trash-panel-plugin udisks"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gdk-pixbuf-2.42.8
+	>=x11-libs/gtk+-3.24.0:3[X]
+	>=xfce-base/exo-4.19.0:=
+	>=xfce-base/libxfce4ui-4.17.6:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre2-10.0:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( dev-libs/libgudev:= )
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? (
+		>=gnome-base/gvfs-1.18.3
+	)
+	udisks? (
+		>=gnome-base/gvfs-1.18.3[udisks,udev]
+		virtual/udev
+	)
+"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre pcre2)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "If you were using an older Xfce version and Thunar fails to start"
+	elog "with a message similar to:"
+	elog "  Failed to register: Timeout was reached"
+	elog "you may need to reset your xfce4 session:"
+	elog "  rm ~/.cache/sessions/xfce4-session-*"
+	elog "See https://bugs.gentoo.org/698914."
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}