dev-python/ndg-httpsclient: Fix namespace support

dev-python/ndg-httpsclient/ndg-httpsclient-0.4.2-r1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides enhanced HTTPS support for httplib and urllib2 using PyOpenSSL"
+HOMEPAGE="
+	https://github.com/cedadev/ndg_httpsclient/
+	https://pypi.python.org/pypi/ndg-httpsclient"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/-/_}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE=""
+
+RDEPEND="dev-python/pyopenssl[$(python_gen_usedep 'python*' pypy)]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${P/-/_}"
+
+# doc build by Makefile in folder documentation is broken
+
+python_install() {
+	distutils-r1_python_install
+
+	# install the namespace (this is the only package in ::gentoo
+	# using it; we'll split it if we add more)
+	python_moduleinto ndg
+	python_domodule ndg/__init__.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name '*.pth' -delete || die
+}