dev-python/flit_core: New package

Package-Manager: Portage-2.3.81, Repoman-2.3.20
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

dev-python/flit_core/Manifest

@@ -0,0 +1 @@
+DIST flit_core-2.1.0.tar.gz 22978 BLAKE2B 87cb5ced56666eb9ae4963628864b66c77758c823b34712770a61a52cb7916196c0d6f51e7b2ad9804b853f27a257966aabef7dd9c95155af8e76f5100b1c9fa SHA512 dfc11cdd62af367b56773e5e0b28763554cd27a272a040a5dd35c8fae4f1e6695b2e2b15b6e63f6aa52df9854874eccc31f6eaf5b349ed85aa33cc5e1d2e1acd

dev-python/flit_core/flit_core-2.1.0.ebuild

@@ -0,0 +1,39 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy{,3} )
+inherit distutils-r1
+
+DESCRIPTION="Simplified packaging of Python modules (core module)"
+HOMEPAGE="https://pypi.org/project/flit-core/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/intreehooks[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	test? ( dev-python/testpath[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	printf -- "from setuptools import setup, find_packages\nsetup(name='${PN//_/-}',version='${PV}',%s)" \
+		"packages=find_packages()" > setup.py || die
+
+	# use toml instead of depricated pytoml
+	sed -e 's:import pytoml as toml:import toml:' \
+		-i flit_core/inifile.py || die
+	sed -e 's:pytoml:toml:' \
+		-i flit_core/build_thyself.py || die
+
+	distutils-r1_python_prepare_all
+}

dev-python/flit_core/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chutzpah@gentoo.org</email>
+    <name>Patrick McLean</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">flit-core</remote-id>
+    <remote-id type="github">takluyver/flit</remote-id>
+  </upstream>
+</pkgmetadata>