dev-python/flask-nav: new package, dependency of flask-bootstrap, vn. 0.5

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1353

Signed-off-by: Ian Delaney <idella4@gentoo.org>

dev-python/flask-nav/Manifest

@@ -0,0 +1 @@
+DIST flask-nav-0.5.tar.gz 11579 SHA256 68a608aae8c6c21453247cc288595c9d52a6b5f3bc31d9a9ee3fd7a1f9c28c47 SHA512 94ebd858754c0ac936b43762cf427c381faa40de86e73b487d6b415d099696e6216b96ad9fefa62516cefd8e51e7ef282e01e1a492783ab696a9fd3602de7e78 WHIRLPOOL f47f6773fd31e4a959437159c5de88f6463ad890e36387cf205ffd42d4de41f375f8264f568bd192ad4f8235cf6e5a6651c2ca3b5dbf14a785f749ab8510a098

dev-python/flask-nav/flask-nav-0.5.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Easily create navigation for Flask applications."
+HOMEPAGE="https://pythonhosted.org/flask-nav/"
+# docs are missing from PyPI tarballs
+# https://github.com/mbr/flask-nav/pull/12
+SRC_URI="https://github.com/mbr/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="
+	dev-python/dominate[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/visitor[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/flask-nav/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@gmail.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">flask-nav</remote-id>
+		<remote-id type="github">mbr/flask-nav</remote-id>
+		<bugs-to>https://github.com/mbr/flask-nav/issues</bugs-to>
+	</upstream>
+</pkgmetadata>