dev-java/jaxen: add 2.0.0

Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
Volkmar W. Pogatzki
2023-03-27 12:24:05 +02:00
committed by Miroslav Šulc
parent 4c81169d8c
commit e81a4c2c98
2 changed files with 68 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST jaxen-1.2.0.tar.gz 282829 BLAKE2B 4d89d4fd3dfd8c4113fe7ecc05597ea9dd743d9c871f320936809016ae8cb3a3d4fb3f935de19463e6c99db1b67eff3545e909b707e81f4c0f114ec0f0e7bb97 SHA512 cecfc62eab1cf6586b28594855bd983679a932dbdc6cbdd07d85a9a9458e78b2e784dfd6287e6e87e4f4443239eefbeac59a7316dae53b818379daaccae56b53
DIST jaxen-2.0.0.tar.gz 348084 BLAKE2B 0dd90e040c865e0c2588f93ead9aadd64d49a8559a7c48255bdf89cca88967a60c8c0817ee4b234352fc0c8c3607e00e08c21df4580be7a889ca748073184f54 SHA512 897d8ee72b2ee3743118e363f66e1ccf5195863e4395dbdffa33b0bd7339663d85946f5e6eb37891e2ebb1572cab610a98a3690bdcc3993a2d2be4ae7920f174
+67
View File
@@ -0,0 +1,67 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
JAVA_PKG_IUSE="doc source test"
MAVEN_ID="jaxen:jaxen:2.0.0"
JAVA_TESTING_FRAMEWORKS="junit"
inherit java-pkg-2 java-pkg-simple
DESCRIPTION="Jaxen is a universal XPath engine for Java"
HOMEPAGE="http://www.cafeconleche.org/jaxen/"
SRC_URI="https://github.com/${PN}-xpath/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${P}"
LICENSE="BSD-2"
SLOT="1.2"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="dom4j jdom xom"
# It seems that most tests depend on dom4j, jdom and xom which all depend back on jaxen
REQUIRED_USE="test? ( dom4j jdom xom )"
CDEPEND="
dom4j? ( dev-java/dom4j:1 )
jdom? ( dev-java/jdom:0 )
xom? ( dev-java/xom:0 )
"
DEPEND="
${CDEPEND}
>=virtual/jdk-1.8:*
"
RDEPEND="
${CDEPEND}
>=virtual/jre-1.8:*
"
JAVA_AUTOMATIC_MODULE_NAME="org.jaxen"
JAVA_SRC_DIR="core/src/java/main"
JAVA_TEST_GENTOO_CLASSPATH="junit"
JAVA_TEST_SRC_DIR="core/src/java/test"
src_prepare() {
java-pkg-2_src_prepare
if use dom4j; then
JAVA_GENTOO_CLASSPATH+=" dom4j-1"
else
rm -rv "${JAVA_SRC_DIR}"/org/jaxen/dom4j || die
fi
if use jdom; then
JAVA_GENTOO_CLASSPATH+=" jdom"
else
rm -rv "${JAVA_SRC_DIR}"/org/jaxen/jdom || die
fi
if use xom; then
JAVA_GENTOO_CLASSPATH+=" xom"
else
rm -rv "${JAVA_SRC_DIR}"/org/jaxen/xom || die
fi
}