app-accessibility/at-spi2-core: Bump to 2.52.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36698
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

app-accessibility/at-spi2-core/Manifest

@@ -1,2 +1,3 @@
 DIST at-spi2-core-2.50.1.tar.xz 567836 BLAKE2B 88916f322efa547be2249388a5f7b698ff7fb9464bc98fa929524616d0d25237328c10678df800b9ce325a3050804e9b0044a43024d06b71381dfc32917700a3 SHA512 d0b342a1ff2a3dd91aa87663412289d1616906c14a37e81b8514882d44981092356dc8a5d5c66b6d980d2cdf22128fff74651a4af6cad73cb62fd3154c5bbeae
 DIST at-spi2-core-2.50.2.tar.xz 569124 BLAKE2B 7a69dbeb68b674d5b4e458dc10ba0e266583216f6a45f1924dee28e848bc124802f5181b0b1cc969eae2dfbb13df56b0c87bb1f347f6e323f6474d02a3543664 SHA512 a1c9ca77d34801b421c13f66d72e6101b23896dd210efbd7931ac0778e30c51a20759796a8c121946f57c1683626fd3ef34f88e5ad6495c20f6ac79fd0a96aa4
+DIST at-spi2-core-2.52.0.tar.xz 574684 BLAKE2B 642cf8a63700ed5d5e20eb356f60c5d5e771d34bb0a373e95c71898ea2318c41484faec736ec44b1162fac22a075ca5f7b4698b105972ea060d107f9afc7f5b9 SHA512 0482cae97cf5e2295ab56f6ae83db9e1047813a1c3c2b6cd6012f95dfabec1f7a93d0045a1a7c3fabb7a389f71dc43f797b2ad9242e97ddf565cf63948ae146b

app-accessibility/at-spi2-core/at-spi2-core-2.52.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson-multilib systemd virtualx xdg
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://wiki.gnome.org/Accessibility https://gitlab.gnome.org/GNOME/at-spi2-core"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="X dbus-broker gtk-doc +introspection systemd"
+REQUIRED_USE="
+	dbus-broker? ( systemd )
+	gtk-doc? ( X )
+"
+
+DEPEND="
+	>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.67.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54.0:= )
+	systemd? ( sys-apps/systemd[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+
+	!<dev-libs/atk-2.46.0
+	!<app-accessibility/at-spi2-atk-2.46.0
+"
+RDEPEND="${DEPEND}
+	dbus-broker? ( sys-apps/dbus-broker )
+"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-python/sphinx
+		dev-util/gdbus-codegen
+		>=dev-util/gi-docgen-2021.1
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_bus=$(usex dbus-broker dbus-broker dbus-daemon)
+		$(meson_use systemd use_systemd)
+		-Dgtk2_atk_adaptor=true
+		-Dsystemd_user_dir="$(systemd_get_userunitdir)"
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_feature introspection)
+		$(meson_feature X x11)
+		-Ddisable_p2p=false
+		-Datk_only=false
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/{libatspi,atk} || die
+		mv "${ED}"/usr/share/doc/libatspi "${ED}"/usr/share/gtk-doc/libatspi/html || die
+		mv "${ED}"/usr/share/doc/atk "${ED}"/usr/share/gtk-doc/atk/html || die
+	fi
+}