From e52afd794af90a39ea18373830dcc2d541d38988 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 2 Nov 2025 10:44:56 +0100
Subject: [PATCH] dev-qt/qtcore: add 5.15.18

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtcore/Manifest              |   2 +
 dev-qt/qtcore/qtcore-5.15.18.ebuild | 162 ++++++++++++++++++++++++++++
 2 files changed, 164 insertions(+)
 create mode 100644 dev-qt/qtcore/qtcore-5.15.18.ebuild

diff --git a/dev-qt/qtcore/Manifest b/dev-qt/qtcore/Manifest
index e64403d9545b2..ea388b6a2080a 100644
--- a/dev-qt/qtcore/Manifest
+++ b/dev-qt/qtcore/Manifest
@@ -1,3 +1,5 @@
 DIST qtbase-5.15-gentoo-patchset-6.tar.xz 8288 BLAKE2B ad9695a528345dd3b8e9ce72b7bdfe8f744f16685a567bbc7862ba6c28e5a426260cb0b73e2573cb3a6f16f1785786898ffb44c90f5d75354b97e5756c7573db SHA512 97bc4d5375e1750a5578439ff320ee2e5e929df1dafe56b4e86f2de8ad26c91dc4002e45ad75d9f936347d49b9f54c0c42f8fc2cb7dfd4f54bf08a210b3bc720
 DIST qtbase-5.15.17-gentoo-kde-1.tar.xz 314280 BLAKE2B a13b0589fab0f43be9b2ba6a669845572ee499363cbe2a8c0975eaf193101960f11efc96f3324d8662a458e41bea42e6d706b3f099f4cfbbea585cab8c3f3f55 SHA512 4b12db534e9fa5f24f597f4e760c8b70d5a41e732b588a9a53f95f4e849cb07a5c8a7f4c3fb690c8b98986a13b1c972b9aac15cfe43ef5b8ab26492b8987169a
+DIST qtbase-5.15.18-gentoo-kde-1.tar.xz 450532 BLAKE2B 172732fe6a2f7dd4718b224d8a8ba7b182ded24f74ee38545d20a17364757153b399cae82b40f425e72b2587ec432f024868078edfe95280242211a040ddd9f6 SHA512 e0257171cf723cb6208a06f28fc95fa07d1239ea9dd3daa79d362146aa53e008398c9e1d95443b84d6d71b835a3f010b957e748f3ec23b77a588d6b372fd0c47
 DIST qtbase-everywhere-opensource-src-5.15.17.tar.xz 51478524 BLAKE2B 1700126de93ecfc2efd128056a295b8fdd2293e2df41e4fefa3d6f61c250d1ae8502a483192ffa85bd1fbd8d086cfd26612c951fb822c19bd0ec3f1b49241968 SHA512 8be592e27279d1009b596535fee95cb6fa8a379e991db5b0f3fa24fcddde7433d2cdfe2cd3fc5fff3f8e112110c5d8fa60c9efd9254053ea08ded5c3f9b73571
+DIST qtbase-everywhere-opensource-src-5.15.18.tar.xz 51492796 BLAKE2B a02f13f2ae8d3994fe5e3fa5b3751cb2981c3203cc4f3859dd4398d6a62101772885acb0c7b1f830ba8e9fbdd64ecfdb2a6074bfedd1bd372b4fc9ceb747467d SHA512 d39c831e6f3ddcd6a50f103ff60a0700b451f137782249508b7447a80066e3e9259c9b5038e6077ccf8df06b6afefec232c3c4dd331d85765089c92571708206
diff --git a/dev-qt/qtcore/qtcore-5.15.18.ebuild b/dev-qt/qtcore/qtcore-5.15.18.ebuild
new file mode 100644
index 0000000000000..d05b9be546df9
--- /dev/null
+++ b/dev-qt/qtcore/qtcore-5.15.18.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+QT5_MODULE="qtbase"
+inherit linux-info flag-o-matic toolchain-funcs qt5-build
+
+DESCRIPTION="Cross-platform application development framework"
+SLOT=5/${QT5_PV}
+
+IUSE="icu old-kernel"
+
+DEPEND="
+	dev-libs/double-conversion:=
+	dev-libs/glib:2
+	dev-libs/libpcre2[pcre16,unicode]
+	sys-libs/zlib:=
+	icu? ( dev-libs/icu:= )
+	!icu? ( virtual/libiconv )
+"
+RDEPEND="${DEPEND}
+	!<dev-qt/designer-${QT5_PV}:5
+	!<dev-qt/qt3d-${QT5_PV}:5
+	!<dev-qt/qtbluetooth-${QT5_PV}:5
+	!<dev-qt/qtcharts-${QT5_PV}:5
+	!<dev-qt/qtconcurrent-${QT5_PV}:5
+	!<dev-qt/qtdatavis3d-${QT5_PV}:5
+	!<dev-qt/qtdbus-${QT5_PV}:5
+	!<dev-qt/qtdeclarative-${QT5_PV}:5
+	!<dev-qt/qtgamepad-${QT5_PV}:5
+	!<dev-qt/qtgraphicaleffects-${QT5_PV}:5
+	!<dev-qt/qtgui-${QT5_PV}:5
+	!<dev-qt/qthelp-${QT5_PV}:5
+	!<dev-qt/qtimageformats-${QT5_PV}:5
+	!<dev-qt/qtlocation-${QT5_PV}:5
+	!<dev-qt/qtmultimedia-${QT5_PV}:5
+	!<dev-qt/qtnetwork-${QT5_PV}:5
+	!<dev-qt/qtnetworkauth-${QT5_PV}:5
+	!<dev-qt/qtopengl-${QT5_PV}:5
+	!<dev-qt/qtpositioning-${QT5_PV}:5
+	!<dev-qt/qtprintsupport-${QT5_PV}:5
+	!<dev-qt/qtquickcontrols-${QT5_PV}:5
+	!<dev-qt/qtquickcontrols2-${QT5_PV}:5
+	!<dev-qt/qtquicktimeline-${QT5_PV}:5
+	!<dev-qt/qtscript-${QT5_PV}:5
+	!<dev-qt/qtscxml-${QT5_PV}:5
+	!<dev-qt/qtsensors-${QT5_PV}:5
+	!<dev-qt/qtserialbus-${QT5_PV}:5
+	!<dev-qt/qtserialport-${QT5_PV}:5
+	!<dev-qt/qtspeech-${QT5_PV}:5
+	!<dev-qt/qtsql-${QT5_PV}:5
+	!<dev-qt/qtsvg-${QT5_PV}:5
+	!<dev-qt/qttest-${QT5_PV}:5
+	!<dev-qt/qtvirtualkeyboard-${QT5_PV}:5
+	!<dev-qt/qtwayland-${QT5_PV}:5
+	!<dev-qt/qtwebchannel-${QT5_PV}:5
+	!<dev-qt/qtwebengine-${QT5_PV}:5
+	!<dev-qt/qtwebsockets-${QT5_PV}:5
+	!<dev-qt/qtwebview-${QT5_PV}:5
+	!<dev-qt/qtwidgets-${QT5_PV}:5
+	!<dev-qt/qtx11extras-${QT5_PV}:5
+	!<dev-qt/qtxml-${QT5_PV}:5
+	!<dev-qt/qtxmlpatterns-${QT5_PV}:5
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/bootstrap
+	src/tools/moc
+	src/tools/rcc
+	src/corelib
+	src/tools/qlalr
+	doc
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	!:network
+	!:sql
+	!:testlib
+	!:xml
+)
+
+pkg_pretend() {
+	use kernel_linux || return
+	get_running_version
+	if kernel_is -lt 4 11 && ! use old-kernel; then
+		ewarn "The running kernel is older than 4.11. USE=old-kernel is needed for"
+		ewarn "dev-qt/qtcore to function on this kernel properly. Bugs #669994, #672856"
+	fi
+}
+
+src_prepare() {
+	# don't add -O3 to CXXFLAGS, bug 549140
+	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
+
+	# fix missing qt_version_tag symbol w/ LTO, bug 674382
+	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
+
+	# Broken with FORTIFY_SOURCE=3
+	#
+	# Our toolchain sets F_S=2 by default w/ >= -O2, so we need
+	# to unset F_S first, then explicitly set 2, to negate any default
+	# and anything set by the user if they're choosing 3 (or if they've
+	# modified GCC to set 3).
+	#
+	# Refs:
+	# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=105078
+	# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=105709
+	# https://bugreports.qt.io/browse/QTBUG-103782
+	# bug #847145
+	if tc-enables-fortify-source ; then
+		# We can't unconditionally do this b/c we fortify needs
+		# some level of optimisation.
+		filter-flags -D_FORTIFY_SOURCE=3
+		# (Qt doesn't seem to respect CPPFLAGS?)
+		append-flags -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2
+	fi
+
+	qt5-build_src_prepare
+
+	# workaround for a79a370c (...Annotate-QMutex-...patch) adding a header
+	qt5_syncqt_version
+}
+
+src_configure() {
+	local myconf=(
+		$(qt_use icu)
+		$(qt_use !icu iconv)
+	)
+	use old-kernel && myconf+=(
+		-no-feature-renameat2 # needs Linux 3.16, bug 669994
+		-no-feature-getentropy # needs Linux 3.17, bug 669994
+		-no-feature-statx # needs Linux 4.11, bug 672856
+	)
+	qt5-build_src_configure
+}
+
+src_install() {
+	qt5-build_src_install
+	qt5_symlink_binary_to_path qmake 5
+
+	local flags=(
+		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
+		OPENGL OPENSSL SSL WIDGETS
+	)
+
+	for flag in ${flags[@]}; do
+		cat >> "${D}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
+
+			#if defined(QT_NO_${flag}) && defined(QT_${flag})
+			# undef QT_NO_${flag}
+			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
+			# define QT_NO_${flag}
+			#endif
+		_EOF_
+	done
+}