dev-python/pyatspi: version bump 2.20.3 → 2.24.0

Package-Manager: Portage-2.3.7, Repoman-2.3.3

dev-python/pyatspi/Manifest

@@ -1 +1,2 @@
 DIST pyatspi-2.20.3.tar.xz 297368 SHA256 628f19cc5790b02ae6ec8580902683520087fba503c06c71257c572108cb5850 SHA512 87f9dccb0be1b85ed850abaf28270c2fd5e52a43dcd94e452f650d6aea8a52bb59d9b9e9d4312bd0fe88d549812c1ddbbceb05955687134613ecd6e1b7af4ace WHIRLPOOL 5468c5cc1fc12fad84c10184014167f69b322757eaaa27e4abc25d376be27a6664a53295d66f0909923920316a4dc8c0d018165d5f5b0e382c84dc9e4252714d
+DIST pyatspi-2.24.0.tar.xz 298228 SHA256 e7ef47a5d387fdc64a01722ef2bcced54c4d6b225fbe34867189e1f88ff0a692 SHA512 ea0c3e5a5a417c4d494cfe33ccfcca1996f417e51f5ccd3508372a0df636fb186b9940d7832681af9b353aa50a9aabd64c5477fdabbc5016794a502396b3d67a WHIRLPOOL e39152ebe90a2e5461bbc663910821306a18a524a687cf72985bcb3601ca428ce85aa05cc6e1b9e30992eee64c1c9e434c5a039f8f6b18d7f3d133c51168a33d

dev-python/pyatspi/pyatspi-2.24.0.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Python binding to at-spi library"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.20.2[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=689957
+	"${FILESDIR}/${PN}-2.6.0-examples-python3.patch"
+)
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir gnome2_src_install
+
+	docinto examples
+	dodoc examples/*.py
+}