From e41f5a0baea8c137643a48f0437bae2d0edaa4e5 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sat, 3 Aug 2024 15:19:12 +0200
Subject: [PATCH] dev-python/graph-tool: add 2.75

Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.75.ebuild | 84 ++++++++++++++++++++
 2 files changed, 85 insertions(+)
 create mode 100644 dev-python/graph-tool/graph-tool-2.75.ebuild

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 3e652f36da912..a5a9e0e086422 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.71.tar.xz 14997876 BLAKE2B c23b4729065ebba43ba3501bca63980a40354e2ff6727ea3b663c60521cdf571ab794eb83f9cfb56909d92e3be90ac5d94c7dcd7f6639cb2c2fb9ee5c675697f SHA512 caedba222e499b81d93d51097c526a8a64dd1f3b91141012c67ffe40532f6168294e430887484522f75709828d280f95cc75bc400a886e71bf73d64efd9b7833
+DIST graph-tool-2.75.tar.xz 15001276 BLAKE2B f329d87becfdee08aafc74ad29f496c1ea973a31d84e6e120056808d9d829cdb79db247991d83461635f06451f68197d7bb815f64ca375a5b0775dac74831d01 SHA512 cb9c0a677bb8dda7dcc56b271f5865675d02509b273fa665c5c84664d645d1b90d015e2a16571bc194fc0583036f3142c5e5e359c815bf13ae882ce6862644fc
diff --git a/dev-python/graph-tool/graph-tool-2.75.ebuild b/dev-python/graph-tool/graph-tool-2.75.ebuild
new file mode 100644
index 0000000000000..933f090ee1fae
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.75.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}