From e35ca299a66e4234d936032d5e2edfd5d6717aed Mon Sep 17 00:00:00 2001
From: Thomas Beierlein <tomjbe@gentoo.org>
Date: Sat, 18 Jul 2026 08:48:09 +0200
Subject: [PATCH] sci-libs/volk: add 3.3.0

Closes: https://bugs.gentoo.org/977410
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
---
 sci-libs/volk/Manifest          |  1 +
 sci-libs/volk/volk-3.3.0.ebuild | 59 +++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 sci-libs/volk/volk-3.3.0.ebuild

diff --git a/sci-libs/volk/Manifest b/sci-libs/volk/Manifest
index dd15826a39707..6e5258335b90c 100644
--- a/sci-libs/volk/Manifest
+++ b/sci-libs/volk/Manifest
@@ -1,2 +1,3 @@
 DIST volk-3.1.2.tar.xz 381388 BLAKE2B c67049921cf0817ff263ae3b0b14b2939e69e461fa731b47f0f923ebe730e67a8715f20738b1991fc9956abd12eccfa50a421460feef12e7678d26a25d73acce SHA512 6fd99b037e2c2481f4886a70021403a8641567a0c0280496194da7ef1b8cf7dbecf91d5bfc1b1c3449788de360206bae5036d796a01bbec211ccf9ccbbc357ee
 DIST volk-3.2.0.tar.xz 399816 BLAKE2B c0cd75f4eb6904c853c9e018777da6a6c17aaa9f73c5656ca5fd330cd5dbcedbf83fc229db9ec0245c5dd0d3b0db6bd652207e3f5bcb7325436cbd2cf8765dd8 SHA512 3142871fe5b06dccd7c3ad399875ad5bbb771e11168f0a146e5a808974c3dcc5de0d6f23c0b72a26389a5f509f47d47146ce18229225737a0c3cd142a6cce61b
+DIST volk-3.3.0.tar.xz 438216 BLAKE2B 38a1bfe03ce3c4f602ac6645f6f9af42fde272f905ddfb9b38b3da005b9dcd7af0ff3c78eb2ce9b93d5b4c236518ae7f86d04dfc9ed7e6f712b9231f1fd01d13 SHA512 cc8d45138dc23668dd3fd50c5b7c9aaf7aa2ecdba1325c896169770b61e6d9cebf6b97382c1d7e71d75af1b13a1f73689d17dad25080046393cfd8becdce5320
diff --git a/sci-libs/volk/volk-3.3.0.ebuild b/sci-libs/volk/volk-3.3.0.ebuild
new file mode 100644
index 0000000000000..f268996463988
--- /dev/null
+++ b/sci-libs/volk/volk-3.3.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} )
+
+#https://github.com/gnuradio/volk/issues/383
+CMAKE_BUILD_TYPE="None"
+inherit cmake python-single-r1
+
+DESCRIPTION="vector optimized library of kernels"
+HOMEPAGE="http://libvolk.org"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gnuradio/volk.git"
+else
+	SRC_URI="https://github.com/gnuradio/volk/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="orc test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/libfmt
+	orc? ( dev-lang/orc )"
+DEPEND="${RDEPEND}
+	$(python_gen_cond_dep 'dev-python/mako[${PYTHON_USEDEP}]')"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_ORC=$(usex orc)
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_TESTING="$(usex test)"
+		-DENABLE_PROFILING=OFF
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# Remove stray python files generated by the build system
+	find "${ED}" -name '*.pyc' -exec rm -f {} \; || die
+	find "${ED}" -name '*.pyo' -exec rm -f {} \; || die
+	python_optimize
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(check_lgpl)"
+	)
+	cmake_src_test
+}