dev-python/APScheduler: Bump to version 3.6.3

Closes: https://bugs.gentoo.org/718846
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Zac Medico <zmedico@gentoo.org>

dev-python/APScheduler/APScheduler-3.6.3.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="In-process task scheduler with Cron-like capabilities"
+HOMEPAGE="https://github.com/agronholm/apscheduler"
+SRC_URI="mirror://pypi/A/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tzlocal-1.2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		www-servers/tornado[${PYTHON_USEDEP}]
+	)"
+
+# Tests that are known to fail (some may be triggered by network-sandbox).
+test_failures=(
+	test_add_class_method_job
+	test_add_instance_method_job
+	test_add_job_conflicting_id
+	test_asyncio_executor_shutdown
+	test_get_all_jobs
+	test_get_next_run_time
+	test_get_pending_jobs
+	test_get_pending_jobs_subsecond_difference
+	test_lookup_job
+	test_lookup_nonexistent_job
+	test_one_job_fails_to_load
+	test_remove_all_jobs
+	test_remove_job
+	test_remove_nonexistent_job
+	test_repr_mongodbjobstore
+	test_repr_redisjobstore
+	test_repr_zookeeperjobstore
+	test_run_coroutine_job
+	test_run_coroutine_job_tornado
+	test_update_job
+	test_update_job_clear_next_runtime
+	test_update_job_next_runtime
+	test_update_job_nonexistent_job
+	test_zookeeper_client_keep_open
+	test_zookeeper_client_ref
+)
+
+python_prepare_all() {
+	sed -i -e /setuptools_scm/d setup.py || die
+	while read -r -d ''; do
+		sed -Ee "s:$(echo "${test_failures[@]}"| sed 's: :|:g'):_\\0:" -i "${REPLY}" || die
+	done < <(grep -rElZ "$(echo "${test_failures[@]}"| sed 's: :|:g')" "${S}")
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test || die "Testing failed with ${EPYTHON}"
+}

dev-python/APScheduler/Manifest

@@ -1 +1,2 @@
 DIST APScheduler-3.5.3.tar.gz 95527 BLAKE2B 3d1bb49a497781d017e2fbd47176186f6449650500c57a141a114f6c610081b9d85553793f9c9f00422d3a299c26c292ab667cfe3866c381bcbf39161133b615 SHA512 dd3e98d0f474511851bdc109a1c65f7f97d221f95d086603d12b3f280285460234724369f05816e1754d58d94adadbec0deb8a0fa63fcd6531914d4a1f4fb3fc
+DIST APScheduler-3.6.3.tar.gz 96309 BLAKE2B 6dcd49ec3ebe4f815a7fd2594c438dfe99d9de720a4319a3c7c202deba1235740e478357dd78ef74ec3610652b23a58f23c1188fcddb3b2e48b160895f3ed06a SHA512 4c348a4f37a7973633554a69635f334b3c293c8942fe853b309b4b65335f5d4d553d7d42fd4661b0e6a36f5e97446d296a2c8971bdb51dad3bc8ee6b6d3b20ba