dev-python/pytest-runner: Bump to v4.0

Package-Manager: Portage-2.3.24, Repoman-2.3.6

dev-python/pytest-runner/pytest-runner-4.0.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Adds support for tests during installation of setup.py files"
+HOMEPAGE="https://pypi.python.org/pypi/pytest-runner https://github.com/pytest-dev/pytest-runner"
+SRC_URI="mirror://pypi/p/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="dev-python/pytest[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? ( ${RDEPEND} )
+"
+
+# Tests require network access to download packages
+RESTRICT="test"
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	esetup.py pytest || die
+}