dev-python/keyring: drop Python 2, add 3.7 and doc

No version of dev-python/secretstorage supports both Python 2 and 3.7.

Package-Manager: Portage-2.3.48, Repoman-2.3.10
Closes: https://github.com/gentoo/gentoo/pull/9782

dev-python/keyring/keyring-13.2.1-r1.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="https://github.com/jaraco/keyring"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="PSF-2"
+KEYWORDS="~amd64"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/secretstorage[${PYTHON_USEDEP}]
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	# Skip an interactive test
+	pytest -vv --override-ini="addopts=--doctest-modules" \
+		--ignore ${PN}/tests/backends/test_kwallet.py \
+		|| die "testsuite failed under ${EPYTHON}"
+}