From dce1771ae0e458f711b2b7fd405cb0f218189796 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Thu, 14 Jan 2021 10:45:05 -0600
Subject: [PATCH] gui-wm/sway: 1.5 cleanup

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
---
 gui-wm/sway/Manifest        |   1 -
 gui-wm/sway/sway-1.5.ebuild | 118 ------------------------------------
 2 files changed, 119 deletions(-)
 delete mode 100644 gui-wm/sway/sway-1.5.ebuild

diff --git a/gui-wm/sway/Manifest b/gui-wm/sway/Manifest
index e0d464dfa6309..c6267a153727e 100644
--- a/gui-wm/sway/Manifest
+++ b/gui-wm/sway/Manifest
@@ -1,2 +1 @@
 DIST sway-1.5.1.tar.gz 5536721 BLAKE2B 4dcb6ca380ef8451ab9219a584598928a79e999bc0b1de0599cb7867c8fd94d54c55a2be9585635b4fd230fd83852141d6fd41ef35dbc4a8fef1bcc2828b3be4 SHA512 3b937249db2875100bc22e99f955a3300d3294a296fb37006fa1468a3986bf4fa8e5197279e3587bd8dc29f31adff8fbdc9ddc840e7be982b73331a05cd06ba5
-DIST sway-1.5.tar.gz 5535966 BLAKE2B e863e97ee897dcd1652d363a09b712932de55da08c88b4858f0aadc29b2cb19d2bda1e5e1184f4e4be6fa54a0136463556f9072f32e2b952d4f12ffd0ee9baf9 SHA512 702e44f8923a4ca05d831dd7ed76165654f113a8b2754d332c509ee844528f47c52b7f21deca78d4a79dad465cbcd0934574fff4ad9bb7a45aec3124dea5bca4
diff --git a/gui-wm/sway/sway-1.5.ebuild b/gui-wm/sway/sway-1.5.ebuild
deleted file mode 100644
index ccdb0da86af97..0000000000000
--- a/gui-wm/sway/sway-1.5.ebuild
+++ /dev/null
@@ -1,118 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit eutils meson
-
-DESCRIPTION="i3-compatible Wayland window manager"
-HOMEPAGE="https://swaywm.org"
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
-else
-	MY_PV=${PV/_rc/-rc}
-	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 arm64 ~ppc64 x86"
-	S="${WORKDIR}/${PN}-${MY_PV}"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="elogind fish-completion +man +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag systemd tray wallpapers X zsh-completion"
-REQUIRED_USE="?? ( elogind systemd )
-	tray? ( || ( elogind systemd ) )"
-
-DEPEND="
-	>=dev-libs/json-c-0.13:0=
-	>=dev-libs/libinput-1.6.0:0=
-	dev-libs/libpcre
-	dev-libs/wayland
-	x11-libs/cairo
-	x11-libs/libxkbcommon
-	x11-libs/pango
-	x11-libs/pixman
-	media-libs/mesa[gles2,libglvnd(+)]
-	elogind? ( >=sys-auth/elogind-239 )
-	swaybar? ( x11-libs/gdk-pixbuf:2 )
-	swaybg? ( gui-apps/swaybg )
-	swayidle? ( gui-apps/swayidle )
-	swaylock? ( gui-apps/swaylock )
-	systemd? ( >=sys-apps/systemd-239 )
-	wallpapers? ( x11-libs/gdk-pixbuf:2[jpeg] )
-	X? ( x11-libs/libxcb:0= )
-"
-if [[ ${PV} == 9999 ]]; then
-	DEPEND+="~gui-libs/wlroots-9999:=[elogind=,systemd=,X=]"
-else
-	DEPEND+="
-		>=gui-libs/wlroots-0.11.0:=[elogind=,systemd=,X=]
-		<gui-libs/wlroots-0.12.0:=[elogind=,systemd=,X=]
-	"
-fi
-RDEPEND="
-	x11-misc/xkeyboard-config
-	${DEPEND}
-"
-BDEPEND="
-	>=dev-libs/wayland-protocols-1.14
-	>=dev-util/meson-0.53.0
-	virtual/pkgconfig
-"
-if [[ ${PV} == 9999 ]]; then
-	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
-else
-	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
-fi
-
-src_prepare() {
-	default
-
-	use swaybar || sed -e "s/subdir('swaybar')//g" -e "/sway-bar.[0-9].scd/d" \
-		-e "/completions\/[a-z]\+\/_\?swaybar/d" -i meson.build || die
-	use swaymsg || sed -e "s/subdir('swaymsg')//g" -e "/swaymsg.[0-9].scd/d" \
-		-e "/completions\/[a-z]\+\/_\?swaymsg/d" -i meson.build || die
-	use swaynag || sed -e "s/subdir('swaynag')//g" -e "/swaynag.[0-9].scd/d" \
-		-e "/completions\/[a-z]\+\/_\?swaynag/d" -i meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dman-pages=$(usex man enabled disabled)
-		-Dtray=$(usex tray enabled disabled)
-		-Dxwayland=$(usex X enabled disabled)
-		$(meson_use wallpapers default-wallpaper)
-		$(meson_use fish-completion fish-completions)
-		$(meson_use zsh-completion zsh-completions)
-		"-Dbash-completions=true"
-		"-Dwerror=false"
-	)
-
-	if use swaybar; then
-		emesonargs+=("-Dgdk-pixbuf=enabled")
-	else
-		emesonargs+=("-Dgdk-pixbuf=disabled")
-	fi
-
-	meson_src_configure
-}
-
-pkg_preinst() {
-	if ! use systemd && ! use elogind; then
-		fowners root:0 /usr/bin/sway
-		fperms 4511 /usr/bin/sway
-	fi
-}
-
-pkg_postinst() {
-	if ! use systemd && ! use elogind; then
-		elog ""
-		elog "If you use ConsoleKit2, remember to launch sway using:"
-		elog "exec ck-launch-session sway"
-		elog ""
-		elog "If your system does not set the XDG_RUNTIME_DIR environment"
-		elog "variable, you must set it manually to run Sway. See wiki"
-		elog "for details: https://wiki.gentoo.org/wiki/Sway"
-	fi
-}