diff --git a/app-text/atril/Manifest b/app-text/atril/Manifest
index ec8be2daa4377..b1e1abdde4313 100644
--- a/app-text/atril/Manifest
+++ b/app-text/atril/Manifest
@@ -1 +1,2 @@
 DIST atril-1.28.1.tar.xz 2100200 BLAKE2B 7c90f1bd8c4e30d1208a5514e8c9153b919443ca0fcbbb7de4db3e74c14330f24fad41f57f1781b243707e724bb9ce4952ca9267755d4482bad7e605421e501f SHA512 a5b0a1bf0d29849384a17723cab402c9e4661a9827b66f2c9c0f2a8500138ca7311c1b6e99dc06d526625d51f9de36cb514ba71fad1c01ea799abdec4f9ecf82
+DIST atril-1.28.3.tar.xz 2244684 BLAKE2B 95adeff24e3a60b51d3280ece9b2a84defc19e3494e58b9e4b3995e9bed1c2ebbfdbd5457dc6b9300de69949c2db91b85b1b721856244fb2aa89641d1c1cea94 SHA512 b53c4223d69da3bdbf9ec89cbea164e77a917479cb4275dafb49947fa416d80ee4eb6b14915d6f4b779b8b2ba3faaae6264695d249ac97d332482e150b8454d5
diff --git a/app-text/atril/atril-1.28.3.ebuild b/app-text/atril/atril-1.28.3.ebuild
new file mode 100644
index 0000000000000..e94e8b96ab484
--- /dev/null
+++ b/app-text/atril/atril-1.28.3.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MATE_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{11..13} )
+inherit mate python-any-r1 virtualx
+
+DESCRIPTION="Atril document viewer for MATE"
+SRC_URI="https://github.com/mate-desktop/${PN}/releases/download/v${PV}/atril-${PV}.tar.xz"
+
+LICENSE="FDL-1.1+ GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+IUSE="caja dbus debug djvu dvi epub +introspection keyring nls +postscript synctex t1lib test tiff xps"
+
+REQUIRED_USE="t1lib? ( dvi )"
+
+DEPEND="
+	app-accessibility/at-spi2-core:2
+	app-text/poppler[cairo]
+	dev-libs/glib:2
+	dev-libs/libxml2:2=
+	>=mate-base/mate-desktop-$(ver_cut 1-2)
+	virtual/zlib:=
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[X(+),introspection?]
+	x11-libs/libICE
+	x11-libs/libSM:0
+	x11-libs/libX11
+	x11-libs/cairo
+	x11-libs/pango
+	caja? ( mate-base/caja[introspection?] )
+	djvu? ( app-text/djvu:0 )
+	dvi? (
+		virtual/tex-base
+		t1lib? ( media-libs/t1lib:5 )
+	)
+	epub? (
+		<dev-libs/mathjax-3
+		net-libs/webkit-gtk:4.1
+	)
+	keyring? ( app-crypt/libsecret )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
+	postscript? ( app-text/libspectre )
+	synctex? ( virtual/tex-base )
+	tiff? ( media-libs/tiff:= )
+	xps? ( app-text/libgxps )
+"
+
+RDEPEND="${DEPEND}
+	gnome-base/gvfs
+	virtual/libintl
+"
+
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/yelp-tools
+	>=dev-util/gdbus-codegen-2.80.5-r1
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-build/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+#RESTRICT="!test? ( test )"
+# Tests use dogtail and require using accessibility services.
+# Until we figure out how to run successfully, don't run tests
+RESTRICT="test"
+
+python_check_deps() {
+	use test && python_has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# Passing --disable-help would drop offline help, that would be inconsistent
+	# with helps of the most of GNOME apps that doesn't require network for that.
+	mate_src_configure \
+		--enable-comics \
+		--enable-pdf \
+		--enable-pixbuf \
+		--enable-previewer \
+		--enable-thumbnailer \
+		$(use_with keyring) \
+		$(use_enable caja) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable djvu) \
+		$(use_enable dvi) \
+		$(use_enable epub) \
+		$(use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable postscript ps) \
+		$(use_enable synctex) \
+		$(use_enable t1lib) \
+		$(use_enable test tests) \
+		$(use_enable tiff) \
+		$(use_enable xps)
+}
+
+src_test() {
+	export GSETTINGS_BACKEND=keyfile
+	gsettings set org.gnome.desktop.interface toolkit-accessibility true || die
+	gsettings set org.mate.interface accessibility true || die
+	virtx emake check
+}