From da714c2157d1ea2d45aee7c646c24f69a93f29c8 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Wed, 12 Nov 2025 13:12:01 -0500
Subject: [PATCH] games-strategy/naev: drop 0.12.5

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 games-strategy/naev/Manifest           |   1 -
 games-strategy/naev/naev-0.12.5.ebuild | 102 -------------------------
 2 files changed, 103 deletions(-)
 delete mode 100644 games-strategy/naev/naev-0.12.5.ebuild

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index c0766c4174a31..04e391fe118c5 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1,2 +1 @@
-DIST naev-0.12.5-source.tar.xz 466103348 BLAKE2B 0e327be29ed4059d21afc2c4aaf80b345a23c1e23068bbc22a66d49794fe2341890d19d4b87a159cb5d3191ee679b753cf3bf79ba61a6835e577541965eca304 SHA512 1f30a674c8fd32a1d52b62b60ac032865993a513284b76417f00f00c30747475af914fb721410c8e378b154e6e4475414d5db3ea8f543a2eea2b3d37d83fecf0
 DIST naev-0.12.6-source.tar.xz 466148336 BLAKE2B 3f5e7e9613a711537171ca7b0cf8f190681a2febb94ef1ff9edcc5e4e9f701e9744c4ffbcf958ce8f3bc862214b35bcf2b690f7e3bd15ef7fa3b62dcfe22b21a SHA512 4d28e9caa26e4c6328b33f17e7c101bc80c6f30540f8d148e7441a9193a3a1a7ee647d501acde7b72b60a9e60ef66774363fdeacefa7c2b7522e278ed44017d2
diff --git a/games-strategy/naev/naev-0.12.5.ebuild b/games-strategy/naev/naev-0.12.5.ebuild
deleted file mode 100644
index 0958c4900a056..0000000000000
--- a/games-strategy/naev/naev-0.12.5.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{11..14} )
-inherit lua-single meson python-any-r1 xdg
-
-DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
-HOMEPAGE="https://naev.org/"
-SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
-
-LICENSE="
-	GPL-3+
-	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
-	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain
-"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# tests are very basic, equivalent to just starting the game and checking if
-# can see the main menu -- but this breaks easily with software rendering and
-# some Xorg/mesa versions, simpler to do manually than try to keep this working
-RESTRICT="test"
-
-# dlopen: libglvnd
-RDEPEND="
-	${LUA_DEPS}
-	app-text/cmark:=
-	dev-games/physfs
-	dev-libs/libpcre2:=
-	dev-libs/libunibreak:=
-	dev-libs/libxml2:=
-	dev-libs/libyaml
-	dev-libs/nativefiledialog-extended
-	media-libs/freetype:2
-	media-libs/libglvnd
-	media-libs/libsdl2[joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	media-libs/sdl2-image[png,webp]
-	net-libs/enet:1.3=
-	sci-libs/cholmod
-	sci-libs/cxsparse
-	sci-libs/openblas
-	sci-libs/suitesparse
-	sci-mathematics/glpk:=
-	virtual/libintl
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	sys-devel/gettext
-	doc? (
-		app-text/doxygen
-		dev-lua/ldoc
-		media-gfx/graphviz
-	)
-"
-
-python_check_deps() {
-	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	lua-single_pkg_setup
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369)
-	sed -i "/subdir('glcheck')/d" test/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		# *can* do lua5-1 but upstream uses+test luajit most (bug #946881)
-		-Dluajit=enabled
-		$(meson_feature doc docs_c)
-		$(meson_feature doc docs_lua)
-	)
-
-	meson_src_configure
-}
-
-src_install() {
-	local DOCS=( CHANGELOG Readme.md )
-	meson_src_install
-
-	if use doc; then
-		dodir /usr/share/doc/${PF}/html
-		mv -- "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
-		rm -r -- "${ED}"/usr/doc || die
-	fi
-
-	rm -r -- "${ED}"/usr/share/doc/naev || die
-}