mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 18:47:16 -08:00
sys-cluster/galera: add 26.4.17
Changed SRC_URI. Original one pointed to .../galera-4/... which contains only the latest release, therefore it is not valid for older releases. New one points to .../galera-4.$(ver_cut 3)/... which translates to .../galera-4.17/... in this case and it should always contain sources for this version. This version also resolves the certificate issue from bug #921955. Bug: https://bugs.gentoo.org/921955 Closes: https://github.com/gentoo/gentoo/pull/33545 Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
This commit is contained in:
@@ -1,3 +1,4 @@
|
||||
DIST galera-26.4.13.tar.gz 1529682 BLAKE2B d7030fd5e3a48ede16f608cca9986de117a54f99cf3d972a5b14623acd84f05f31f5cdbbc3032bf5caa8e0486f418ac07c8f87287bb14a8164507c558876ae61 SHA512 e548048eac5fceb0bea1ae736abc6c488d175bc71a3cfb963675232688392ecb5dcc64ddd8e78ceda40e26b94b806d3c34bd9fc9765ebc047b5a5ce28ff7efea
|
||||
DIST galera-26.4.14.tar.gz 1532285 BLAKE2B c647332a1a70609fbe3197653df2e24ccd0c5e053b1c9ef4d3de20bc70d8f2363090c6296e9e81eeb92a625c85d67b4f298db8e34862c7deb907baf13bae2e45 SHA512 f9bb3d1d503ed7f90cfc5596e68e8cf77683d2d7e6ddb45d0a6618bbc6a31ad2caa80933f6724734ec4ae416b37d7d7ec61e1bf0b87cefd4c959954266a2fb26
|
||||
DIST galera-26.4.15.tar.gz 1532571 BLAKE2B 8aa5c6027b4cfe7f41c9d431315a4a12b9ea45896743bafa296470e8e3f0613e8974e3daea0d7c89c3e2d014692fb7d10f4a64588add569a197546dcd0f0108d SHA512 b866610c00df344ea8c9cc948fadfa4be808ee6bb100fec470dee006458d81ec704db156d320889610bff9b944023963f624b8672596a282c7658c55d99ffca6
|
||||
DIST galera-26.4.17.tar.gz 1541975 BLAKE2B 7b12a9c056e45fc0614910a5f6eb1127e3613aa7b212db94594330ddd048de4982cbb1d36a75c08da0aa31a9a08a5632686e867b967291bb269835e37a6efcb3 SHA512 c11fecb6c9e142643f594275d6ff486d7a3615016691373831e57221f9bbfdc086202757068a2cc9308049b3499aa64dcc6f066dcf6437d25a4c546b19ac8fa3
|
||||
|
||||
@@ -0,0 +1,71 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit cmake
|
||||
|
||||
MY_PN="${PN}-4"
|
||||
MY_P="${MY_PN}-${PV}"
|
||||
|
||||
DESCRIPTION="Synchronous multi-master replication engine that provides the wsrep API"
|
||||
HOMEPAGE="https://galeracluster.com"
|
||||
SRC_URI="
|
||||
https://releases.galeracluster.com/${MY_PN}.$(ver_cut 3)/source/${MY_P}.tar.gz
|
||||
-> ${P}.tar.gz
|
||||
"
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
LICENSE="GPL-2 BSD"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
|
||||
IUSE="garbd ssl"
|
||||
|
||||
RDEPEND="
|
||||
ssl? ( dev-libs/openssl:= )
|
||||
dev-libs/boost:=
|
||||
"
|
||||
# TODO: Make check dep optional
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
>=dev-cpp/asio-1.22
|
||||
dev-libs/check
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
cmake_src_prepare
|
||||
|
||||
# Remove bundled dev-cpp/asio
|
||||
rm -r asio || die "Failed to remove bundled asio"
|
||||
|
||||
# Remove optional garbd daemon
|
||||
if ! use garbd ; then
|
||||
rm -r garb || die "Failed to remove garbd daemon"
|
||||
sed -i '/add_subdirectory(garb)/d' CMakeLists.txt || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DGALERA_WITH_SSL=$(usex ssl)
|
||||
)
|
||||
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
dodoc scripts/packages/README scripts/packages/README-MySQL
|
||||
|
||||
if use garbd ; then
|
||||
newconfd "${FILESDIR}"/garb.cnf garbd
|
||||
newinitd "${FILESDIR}"/garb.init garbd
|
||||
doman man/garbd.8
|
||||
|
||||
pushd "${BUILD_DIR}" || die
|
||||
dobin garb/garbd
|
||||
fi
|
||||
|
||||
pushd "${BUILD_DIR}" || die
|
||||
exeinto /usr/$(get_libdir)/galera
|
||||
doexe libgalera_smm.so
|
||||
}
|
||||
Reference in New Issue
Block a user