diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index c02cc603ac80a..963ad81df53ee 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1 +1,2 @@
 DIST kwave-26.04.3.tar.xz 6553844 BLAKE2B 47a56874a2cf1d06c4cf95573477e809d1bfbcafe641719c74774a10aff2671c209bcf807f8cef3f1d0cb91f9e21c1b93758c2a77736a120e3578ef75e89263c SHA512 293bcdbfc963a6232ead25fa9c08322a6681be1ef6c5d7c20c8a5e8e366656511a4e1c1bb1a06a2e99ad4e25993af8b77eeeacbaf049cf3662de5080491461e7
+DIST kwave-26.08.0.tar.xz 6564380 BLAKE2B 6c8d24b08abe04fff3ebb8a1c86beaa710288576c5b7f12eba4497d9070d02b764037a6b7bedbb6537a08320394b5c29feb872895de64df0b6b759ff55b4f223 SHA512 b022f4b3ede2409f0037d32280b1fd7d685b3898acfbd91f35c2ceb2a572f152f73cb9e8264e5f2251c7d36e98e37946af9dcbb72984405fa1c4539e3a27d5cf
diff --git a/kde-apps/kwave/kwave-26.08.0.ebuild b/kde-apps/kwave/kwave-26.08.0.ebuild
new file mode 100644
index 0000000000000..7826c4f3c9f67
--- /dev/null
+++ b/kde-apps/kwave/kwave-26.08.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=6.27.0
+QTMIN=6.11.2
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Sound editor built on KDE Frameworks that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:6 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README.md TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}