dev-python/msgpack-0.6.2: version bump, add py38 and pypy3

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

dev-python/msgpack/msgpack-0.6.2.ebuild

@@ -0,0 +1,38 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="MessagePack (de)serializer for Python"
+HOMEPAGE="https://msgpack.org
+	https://github.com/msgpack/msgpack-python/
+	https://pypi.org/project/msgpack/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="+native-extensions test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	native-extensions? (
+		$(python_gen_cond_dep '>=dev-python/cython-0.16[${PYTHON_USEDEP}]' 'python*')
+	)
+	test? (	dev-python/six[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Remove pre-generated cython files
+	rm msgpack/{_packer,_unpacker,_cmsgpack}.pyx || die
+
+	if ! use native-extensions ; then
+		sed -i -e "/have_cython/s:True:False:" setup.py || die
+	fi
+	distutils-r1_python_prepare_all
+}