From d65aba258a16a2b72a261fa461b582cf6fb55cbe Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 14 Sep 2026 03:41:55 +0200
Subject: [PATCH] dev-python/pdm: Bump to 2.29.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm/Manifest          |  1 +
 dev-python/pdm/pdm-2.29.1.ebuild | 89 ++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)
 create mode 100644 dev-python/pdm/pdm-2.29.1.ebuild

diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index df4d982d38b37..06ef20489e845 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
 DIST pdm-2.29.0.tar.gz 2707949 BLAKE2B db0bd4f076b20424555ff929ad4a76988c1ca41236d1d906a8a8c386a98955de2dd8b87439340a7fb785c4b4959a640a37fd771e7233fe53c0dd45eedaeb790e SHA512 81ab404adf5bfd2f9be8b016d2cb4f0cbc32bf38aab1b4c4b999e7a29404bf3fa53fcdfb07793498d056260a16ef104bb2ee6fe8cda77ebaf5ceb7eaef276560
+DIST pdm-2.29.1.tar.gz 2713906 BLAKE2B d610993a0120f2517aa6c575f8fd9754552e1b5895f8765d58051733ac9c9d7df3de549d3c96ea04b03f3177b32914a3a725c0aee324a2ed52b47e7b955ef4ca SHA512 38d2924f0933cbb32468950bdeb4866d8c49d22f34dbcae081d9dae7f84eedae22535a9c39f2c65457abe9b9bad828050fa6808ac8940ed46da9de63ef0a254f
diff --git a/dev-python/pdm/pdm-2.29.1.ebuild b/dev-python/pdm/pdm-2.29.1.ebuild
new file mode 100644
index 0000000000000..a5ff402aeb42b
--- /dev/null
+++ b/dev-python/pdm/pdm-2.29.1.ebuild
@@ -0,0 +1,89 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/argcomplete-3.6.3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.7.1[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/installer-1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.10.07[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+	# remove pkgutil namespace magic, as it doesn't work and makes
+	# dev-python/pdm-backend tests test the wrong package
+	rm src/pdm/__init__.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+		# TODO: random regression?
+		tests/cli/test_python.py::test_find_python
+		# TODO
+		tests/test_formats.py::test_export_from_pylock_not_empty
+	)
+	local EPYTEST_IGNORE=(
+		# requires missing tasks file, probably irrelevant to us
+		tests/test_doc_generation.py
+	)
+
+	epytest -m "not network and not integration and not path"
+}