dev-python/pexpect: version bump to 4.2.1, EAPI bump.

Removed the old 4.0.1 because it was marked unstable and pretty old.
Removed the removal of broken test-cases.
Removed ~amd64-fbsd as dependency ptyprocess also doesn't have it.

Gentoo-Bug: https://bugs.gentoo.org/527006
Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2731

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

dev-python/pexpect/pexpect-4.2.1.ebuild

@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for spawning child applications and responding to expected patterns"
+HOMEPAGE="
+	http://pexpect.sourceforge.net/
+	https://pypi.python.org/pypi/pexpect/
+	https://github.com/pexpect/pexpect/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/ptyprocess-0.5[${PYTHON_USEDEP}]"
+DEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	py.test tests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples 
+	fi
+	distutils-r1_python_install_all
+}