net-misc/smb4k: add 4.0.5

Bug: https://bugs.gentoo.org/967312
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-misc/smb4k/Manifest

@@ -1 +1,2 @@
 DIST smb4k-4.0.4.tar.xz 4853384 BLAKE2B 7596b3e610b28f200939335574a6e7dd1af4c4f89fd1e594e344619225e2a3a75b0ac8a328f82870c1647c4cb2c995748502fe5e0a661ba95bf1ffb8745e071f SHA512 c98e8a510d639284d44ad64a68cdf93b626893600eb28767f2f1ba0a737c9dbe3f15f23d2571bb234a2aeca4bd734c171f7d57b27ca8ffd2b77715f6b01679e2
+DIST smb4k-4.0.5.tar.xz 4880008 BLAKE2B 0af369db1754215f6a326ce118af3cbcc84f76c25536b3a06757f32d3d8515a632e9850a62441a321c3214251f0d3ac69dae38f6f316aa4461cc0f354ce8a480 SHA512 182ba8abbe9ce84961231724d9176c85e695a2227e6c13ac293eaa30ff856e619f0841ed414d3ff0cfc48be8e3efc93374e0f67dfd20f7dff33b4774576a9809

net-misc/smb4k/smb4k-4.0.5.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.9.0
+QTMIN=6.8.1
+inherit ecm kde.org xdg
+
+DESCRIPTION="Advanced network neighborhood browser"
+HOMEPAGE="https://apps.kde.org/smb4k/
+https://sourceforge.net/p/smb4k/home/Home/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+discovery plasma"
+
+DEPEND="
+	>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
+	>=dev-qt/qtbase-${QTMIN}:6[gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdnssd-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	net-fs/samba[cups]
+	discovery? (
+		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
+		>=net-libs/kdsoap-ws-discovery-client-0.4.0
+	)
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+	plasma? (
+		>=kde-frameworks/kirigami-${KFMIN}:6
+		kde-plasma/libplasma:6
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSMB4K_WITH_WS_DISCOVERY=$(usex discovery)
+		-DSMB4K_INSTALL_PLASMOID=$(usex plasma)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "Users of Samba 4.7 and above please note that for the time being,"
+	elog "the following setting has to be added to or changed in the [global]"
+	elog "section of the smb.conf file:"
+	elog
+	elog "[global]"
+	elog "client max protocol = NT1"
+}