dev-python/fido2: bump to 0.5.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Göktürk Yüksek <gokturk@gentoo.org>

dev-python/fido2/Manifest

@@ -1,2 +1,3 @@
 DIST fido2-0.3.0.tar.gz 125907 BLAKE2B 95054f258c775ac3b4f65608fd3b62ec4165a568c237064ebb66da1ca6ae899a3d88b5613e9dd4be87c05068ebd698be452dd3467800317e5894092216196e12 SHA512 c6ea83e104d77350413156eba4c1aa2635b77ae00d157dce61e5a8539c65aca4dd1dfc5303f9d408359582eeb98ae558aa1e2043a9b1dfcb23415eb8bc9c6a09
 DIST fido2-0.4.0.tar.gz 141714 BLAKE2B 3d57ef1598d2c84cea8a98e75cdef96b77807d4eb5951515560b43655a48bb0816c4e05ef39314b13b6bad84509e09145aeab5727a9fc6cba65ddf42f588b007 SHA512 4eb95a95e1f5b8b49267bc0a11e5501bd041a211ac8a6249ff9cc26ebb0b155b9d16494c18391a14feecb197d61dc50c8530b2ab38ba7e9dc600276abd6f8bcf
+DIST fido2-0.5.0.tar.gz 161562 BLAKE2B 20d4f6c4e54366a26d5a56a84a6ff84bec0f0e22107aa612db721df8a5186a2129373ae609fb58a27008dc700b4b92d607fc2bf16aab7ac6bff8d9e7219204aa SHA512 fa83848e179b9208e2a701a3330faa1dde75e5e23133540eaec896145dbde376bc424a5e59865d3cf90c5765882e22530e96df2491101d2b5dcb22cfc4bcbb87

dev-python/fido2/fido2-0.5.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+inherit distutils-r1
+
+DESCRIPTION="Python based FIDO 2.0 library"
+HOMEPAGE="https://github.com/Yubico/python-fido2"
+SRC_URI="https://github.com/Yubico/python-fido2/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD-2 MIT MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python2_7)
+	examples? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	touch "${S}"/test/__init__.py || die
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r "${S}"/examples/.
+		docompress -x "/usr/share/doc/${PF}/examples"
+	fi
+}