dev-python/scrapy: version bump to 1.4.0.

Bug: https://bugs.gentoo.org/626550
Closes: https://github.com/gentoo/gentoo/pull/6029

dev-python/scrapy/Manifest

@@ -1 +1,2 @@
 DIST scrapy-1.0.3.tar.gz 1006911 SHA256 725eb5906b35076ad112b1b0ac27c68dd684e72514eddf95bc7ace64c04b2bb2 SHA512 bf61d449d7309de0ebdc36c73371d01518ee5cfa5d4ac1b68ee42389466ee15dba82690dbc885aa6bc1b9fe0b2e29a03fb3a3af3889842e1039e3a81749fc0c0 WHIRLPOOL 0dee3a82a0368f50420d484252d5d138c8a3bf8257715dad5d74419a7a852ef5d21aef5b52e9959f8f08d7dcdd58988221faff38d9a8d530406cfb83fbb031f9
+DIST scrapy-1.4.0.tar.gz 1114816 SHA256 7889790a5684ffeafe4389dd819e0e700ea34cf067bd36a06c2e05ad4adc7b03 SHA512 1442cae1a26b5c7c8c27998ec6ef9ab374111221180a5933d53aff0c7aeb31102882c387581c1455c1dd246e11f0c0f5ab5989a21037204e5314054e303f7312 WHIRLPOOL 32e7fa565716657072faa817de7e9f1d01e2599dcb3861664ea960097dc78b7bc5bf3a410703eb4ad6995ded3568c2e394b4b8201ed84751cc1ecc88c8ad73a2

dev-python/scrapy/scrapy-1.4.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A high-level Python Screen Scraping framework"
+HOMEPAGE="https://github.com/scrapy/scrapy/ https://pypi.python.org/pypi/Scrapy/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boto doc ibl test ssl"
+
+RDEPEND="
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	dev-libs/libxml2[python,${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	>=dev-python/parsel-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.4[${PYTHON_USEDEP}]
+	ibl? ( dev-python/numpy[${PYTHON_USEDEP}] )
+	ssl? (
+		>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}] )
+	boto? ( dev-python/boto3[${PYTHON_USEDEP}] )
+	>=dev-python/twisted-14.0[${PYTHON_USEDEP}]
+	>=dev-python/w3lib-1.8.0[${PYTHON_USEDEP}]
+	dev-python/queuelib[${PYTHON_USEDEP}]
+	>=dev-python/cssselect-0.9[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	dev-python/service_identity[${PYTHON_USEDEP}]
+	"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		=net-proxy/mitmproxy-0.10.1[${PYTHON_USEDEP}]
+		=dev-python/netlib-0.10.1[${PYTHON_USEDEP}]
+		dev-python/jmespath[${PYTHON_USEDEP}]
+		dev-python/testfixtures[${PYTHON_USEDEP}]
+		net-ftp/vsftpd
+	)"
+# pytest-twisted listed as a test dep but not in portage.
+# Testsuite currently survives without it, so appears optional
+
+REQUIRED_USE="test? ( ssl boto )"
+
+python_prepare_all() {
+	# https://github.com/scrapy/scrapy/issues/1464
+	# Disable failing tests known to pass according to upstream
+	# Awaiting a fix planned by package owner.
+	sed -e 's:test_https_connect_tunnel:_&:' \
+		-e 's:test_https_connect_tunnel_error:_&:' \
+		-e 's:test_https_tunnel_auth_error:_&:' \
+		-e 's:test_https_tunnel_without_leak_proxy_authorization_header:_&:' \
+		-i tests/test_proxy_connect.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		PYTHONPATH="${S}" emake -C docs html || die "emake html failed"
+	fi
+}
+
+python_test() {
+	py.test ${PN} tests || die "tests failed"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}