www-client/falkon: 25.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

www-client/falkon/Manifest

@@ -1 +1,2 @@
 DIST falkon-25.08.3.tar.xz 2699136 BLAKE2B 2f628f1a09e789fdf9860e5c2d6a1316b99ebaea79eef8c9ffdc9aadde88247db6a363782febc3192e02198833380601bafa2a33fb10c3d33cb493fb6639ca0b SHA512 1e5764075fb366ac330cdfaa281d508bff178945d8a42edfffc92552f0abb4386db161e1bbd36e678f8e43a68975d188f5cd5207c5c9294ffc2c89ce22ca7ff5
+DIST falkon-25.12.0.tar.xz 2705504 BLAKE2B 28227c015f67fb48275fc9b274c0b397a99f03aabb85e634f31f2a7814e4864e147e051b706f015cae99c73049a5afdcc28f008ec4c70953d5adeacbd23a015a SHA512 404b566c75e028b3a288e097e51ccf2b1676c3c6fac051a88abee9f22ac1dc9c4f8a2e5ec7574f0b00bd77c8d22cc1f8a313ad5284447076fc1a5c9cae02161f

www-client/falkon/falkon-25.12.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.19.0
+QTMIN=6.9.1
+PYTHON_COMPAT=( python3_{11..13} )
+inherit ecm gear.kde.org python-single-r1 xdg
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtwebchannel-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	virtual/libintl
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:6
+		>=kde-frameworks/kcrash-${KFMIN}:6
+		>=kde-frameworks/kio-${KFMIN}:6
+		>=kde-frameworks/kjobwidgets-${KFMIN}:6
+		>=kde-frameworks/kwallet-${KFMIN}:6
+		>=kde-frameworks/purpose-${KFMIN}:6
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside-${QTMIN}:6[gui,positioning,uitools(-),webengine,widgets,\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+"
+BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF6Wallet)
+		$(cmake_use_find_package kde KF6KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}