dev-python/ipykernel: Version bump 5.1.3.

Drop ~amd64-linux and ~x86-linux keywords, because their
  dependencies are not met.

  Add missing / to ${ED}.

Bug: https://github.com/gentoo/gentoo/pull/13988
Bug: https://bugs.gentoo.org/702458
Closes: https://github.com/gentoo/gentoo/pull/14001
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Signed-off-by: Benda Xu <heroxbd@gentoo.org>
Package-Manager: Portage-2.3.81, Repoman-2.3.20

dev-python/ipykernel/ipykernel-5.1.3.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 "
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/ipython-6[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1.0[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_install() {
+	distutils-r1_python_install
+
+	# bug 628222, specify python 2 or 3.
+	sed -e "/language/!s:python:${EPYTHON%.*}:" \
+		-i "${ED}"/usr/share/jupyter/kernels/${EPYTHON%.*}/kernel.json || die
+}