mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
kde-plasma/plasma-desktop: drop 6.3.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
parent
f238d4dd0c
commit
ce92f2ad22
@ -1,4 +1,3 @@
|
||||
DIST plasma-desktop-6.2.5.tar.xz 16342172 BLAKE2B c59e4069360ee17ccc4c96a9d02eb34aeb2baf082d346354cfe29390a111aa519afc5c5f514ef36e193df583c3bb9b3dd56ee3d9e441f7f8f528f326eaf7f397 SHA512 c0d2776fa740dcfa072db606e7eb852e4c50b0b06a1e097c882addbbb04c81fc3d20384ba2cd8abce8d983f99e71824b770c6dc5420e5510f779b9e7eff4a2a2
|
||||
DIST plasma-desktop-6.3.3.tar.xz 16879628 BLAKE2B 63e08e8f8ecd354693bc8ec3d9c1a94151a581ff1f48106e103c0be705c05785b6c00e5a4c9ed642d21567331e7c84fffd6eb172e27df08abaa5423a6686470e SHA512 d6ccf9d808b1c960ce25008e1acffb103d72eff5d989a88b4c3b76a2a67d8c4d7b3dfd72057e594e1baff3be404e7883590992b5ef9eb267cf7bead656821855
|
||||
DIST plasma-desktop-6.3.4.tar.xz 16881320 BLAKE2B 8ffc74db1fe3c734d814e3354e1b6d513a144cc92ef99260516a5cb3f017ad5074641a07884291c1c2fd75268788165fceba7365e7863a9337d60a7b03bf7711 SHA512 4d288be183ac8c7cd3284f80fdf3c922b18aad6e64d60bdf266367994b692de5d511f1b61d093b7509114806b8c334470f5f0e9872b1130327260819eea8bee0
|
||||
DIST plasma-desktop-override-include-dirs-4.tar.xz 6360 BLAKE2B 8d4340f7b520ec2a4d47d7679028d5d75ceb141877248f7c411a082197ca9c0735ff2d21bd30333236c50dcae8bbdabd41164daa392b803504d2707ffd013960 SHA512 5273df12260d90e7aacc90b9ed7f6f1868c8996e2609229c59a771b3fb541b720f53fe2c2198d9d91870b05d06797bc4b2cec5afcf97d8b2b754f0da197584a1
|
||||
|
||||
@ -1,188 +0,0 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="optional"
|
||||
ECM_TEST="true"
|
||||
KFMIN=6.10.0
|
||||
QTMIN=6.8.1
|
||||
inherit ecm plasma.kde.org optfeature xdg
|
||||
|
||||
DESCRIPTION="KDE Plasma desktop"
|
||||
XORGHDRS="${PN}-override-include-dirs-4"
|
||||
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${XORGHDRS}.tar.xz"
|
||||
|
||||
LICENSE="GPL-2" # TODO: CHECK
|
||||
SLOT="6"
|
||||
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
IUSE="ibus input_devices_wacom scim screencast sdl +semantic-desktop webengine"
|
||||
|
||||
RESTRICT="test" # missing selenium-webdriver-at-spi
|
||||
|
||||
# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
|
||||
# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
|
||||
COMMON_DEPEND="
|
||||
dev-libs/icu:=
|
||||
>=dev-qt/qt5compat-${QTMIN}:6[qml]
|
||||
>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,network,sql,widgets,xml]
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:6
|
||||
>=dev-qt/qtsvg-${QTMIN}:6
|
||||
>=kde-frameworks/attica-${KFMIN}:6
|
||||
>=kde-frameworks/karchive-${KFMIN}:6
|
||||
>=kde-frameworks/kauth-${KFMIN}:6
|
||||
>=kde-frameworks/kbookmarks-${KFMIN}:6
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
>=kde-frameworks/kcodecs-${KFMIN}:6
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:6
|
||||
>=kde-frameworks/kconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kcrash-${KFMIN}:6
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kded-${KFMIN}:6
|
||||
>=kde-frameworks/kglobalaccel-${KFMIN}:6
|
||||
>=kde-frameworks/kguiaddons-${KFMIN}:6
|
||||
>=kde-frameworks/ki18n-${KFMIN}:6
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:6
|
||||
>=kde-frameworks/kio-${KFMIN}:6
|
||||
>=kde-frameworks/kitemmodels-${KFMIN}:6
|
||||
>=kde-frameworks/kitemviews-${KFMIN}:6
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:6
|
||||
>=kde-frameworks/knotifications-${KFMIN}:6
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kpackage-${KFMIN}:6
|
||||
>=kde-frameworks/kparts-${KFMIN}:6
|
||||
>=kde-frameworks/krunner-${KFMIN}:6
|
||||
>=kde-frameworks/kservice-${KFMIN}:6
|
||||
>=kde-frameworks/ksvg-${KFMIN}:6
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:6
|
||||
>=kde-frameworks/solid-${KFMIN}:6
|
||||
>=kde-frameworks/sonnet-${KFMIN}:6
|
||||
>=kde-plasma/kwin-${KDE_CATV}:6
|
||||
>=kde-plasma/libksysguard-${KDE_CATV}:6
|
||||
>=kde-plasma/libplasma-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-activities-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-activities-stats-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-workspace-${KDE_CATV}:6[screencast?]
|
||||
>=kde-plasma/plasma5support-${KDE_CATV}:6
|
||||
media-libs/libcanberra
|
||||
x11-libs/libX11
|
||||
x11-libs/libxcb
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXi
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/libxkbfile
|
||||
ibus? (
|
||||
app-i18n/ibus
|
||||
dev-libs/glib:2
|
||||
x11-libs/xcb-util-keysyms
|
||||
)
|
||||
input_devices_wacom? (
|
||||
dev-libs/wayland
|
||||
dev-libs/libwacom:=
|
||||
>=dev-qt/qtwayland-${QTMIN}:6
|
||||
)
|
||||
scim? ( app-i18n/scim )
|
||||
sdl? ( media-libs/libsdl2[joystick] )
|
||||
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:6 )
|
||||
webengine? (
|
||||
kde-apps/kaccounts-integration:6
|
||||
>=net-libs/accounts-qt-1.17[qt6(+)]
|
||||
)
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
dev-libs/boost
|
||||
x11-base/xorg-proto
|
||||
input_devices_wacom? ( >=dev-libs/wayland-protocols-1.25 )
|
||||
test? (
|
||||
>=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
|
||||
>=kde-plasma/kactivitymanagerd-${KDE_CATV}:6
|
||||
)
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
!<kde-plasma/plasma-workspace-6.0.80
|
||||
dev-libs/kirigami-addons:6
|
||||
>=dev-qt/qtwayland-${QTMIN}:6
|
||||
>=kde-frameworks/kirigami-${KFMIN}:6
|
||||
>=kde-frameworks/qqc2-desktop-style-${KFMIN}:6
|
||||
>=kde-plasma/oxygen-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-mimeapps-list-3
|
||||
media-fonts/noto-emoji
|
||||
sys-apps/util-linux
|
||||
x11-apps/setxkbmap
|
||||
x11-misc/xdg-user-dirs
|
||||
screencast? ( >=kde-plasma/kpipewire-${KDE_CATV}:6 )
|
||||
webengine? ( >=net-libs/signon-oauth2-0.25_p20210102[qt6(+)] )
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/intltool
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
virtual/pkgconfig
|
||||
input_devices_wacom? ( dev-util/wayland-scanner )
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-6.1.80-override-include-dirs.patch" # downstream patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
|
||||
if ! use ibus; then
|
||||
sed -e "s/XCB_XCB_FOUND AND XCB_KEYSYMS_FOUND/false/" \
|
||||
-i applets/kimpanel/backend/ibus/CMakeLists.txt || die
|
||||
fi
|
||||
|
||||
# TODO: try to get a build switch upstreamed
|
||||
if ! use scim; then
|
||||
sed -e "s/^pkg_check_modules.*SCIM/#&/" -i CMakeLists.txt || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_KCM_MOUSE_X11=ON
|
||||
-DBUILD_KCM_TOUCHPAD_X11=ON
|
||||
-DXORGLIBINPUT_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
|
||||
-DXORGSERVER_INCLUDE_DIRS="${WORKDIR}/${XORGHDRS}"/include
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON # not packaged
|
||||
$(cmake_use_find_package ibus GLIB2)
|
||||
-DBUILD_KCM_TABLET=$(usex input_devices_wacom)
|
||||
$(cmake_use_find_package sdl SDL2)
|
||||
$(cmake_use_find_package semantic-desktop KF6Baloo)
|
||||
$(cmake_use_find_package webengine AccountsQt6)
|
||||
$(cmake_use_find_package webengine KAccounts6)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# parallel tests fail, foldermodeltest,positionertest hang, bug #646890
|
||||
# test_kio_fonts needs D-Bus, bug #634166
|
||||
# lookandfeel-kcmTest is unreliable for a long time, bug #607918
|
||||
local myctestargs=(
|
||||
-j1
|
||||
-E "(foldermodeltest|positionertest|test_kio_fonts|lookandfeel-kcmTest)"
|
||||
)
|
||||
|
||||
ecm_src_test
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake_src_install
|
||||
|
||||
# Provide kde-mimeapps.list with distribution kde-plasma/plasma-mimeapps-list
|
||||
rm "${ED}"/usr/share/applications/kde-mimeapps.list || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -z "${REPLACING_VERSIONS}" ]]; then
|
||||
optfeature "screen reader support" "app-accessibility/orca"
|
||||
fi
|
||||
xdg_pkg_postinst
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user