dev-python/astroquery: initial import

Package-Manager: portage-2.2.27

dev-python/astroquery/Manifest

@@ -0,0 +1 @@
+DIST astroquery-0.3.1.tar.gz 2786634 SHA256 ad67bf4f31bc9e0c45621a19f7200d701ff7b5df2d78e9ba7095e65a2f69c50d SHA512 e92f10dcdc4ced5c6841b35b7afc0ae645231810ae2951a04cc1c014819096bfd9296b1bc6d0f925a59e64e9011ec3f2436e36d0ec2181d271eb0aeba80906c8 WHIRLPOOL ac91041f9bce69945000ded78a39992d724ce7a32937c4803daa51556c2b8ef4984c8da5b6ae1ae4b1e1747ae6ce83d13ee180bbe361b0aaa9ae6a7900010000

dev-python/astroquery/astroquery-0.3.1.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of packages to access online astronomical resources"
+HOMEPAGE="https://github.com/astropy/astroquery"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+DOCS=( README.rst )
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/aplpy[${PYTHON_USEDEP}]
+			dev-python/pyregion[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	sed -i -e "s/= 'APLpy'/= 'aplpy'/" astroquery/conftest.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

dev-python/astroquery/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+		Astroquery is a package containing a collection of tools to use
+		online astronomical databases. It integrates with Astropy and aims
+		to support many services with a uniform API.
+	</longdescription>
+  <upstream>
+    <remote-id type="pypi">astroquery</remote-id>
+    <remote-id type="github">astropy/astroquery</remote-id>
+  </upstream>
+</pkgmetadata>