diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index c1baeb38c671f..3b45d9782cd48 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-2.1.0.tar.gz 640535 BLAKE2B c269527d9863b7991be24cb6fac43cfbe8cea23fbbdbb8ff9699bce9653e014a0def7439ffbced1658bc54bb328119c2d3ddea9a83e0a3c2cbcd3d21500a1f28 SHA512 215c33e29ab18e8ebb693e4d9da2bf51750e1558ef20b13c4d301a803a5dda0e1c00edbfa019717043ea777e8c47e1772ab9334b12cc08e7fe9196121c6bd287
+DIST rq-2.3.2.tar.gz 649216 BLAKE2B 8fca0c9008717353b99d7fba502554cd85378e69bef3f5b78acfdc168ecfc95f1644e3ae30a6ace7958a9ad8cc982b155a606b1ae745fabd0caecd1ae353d374 SHA512 b218a6ed7129cab4c148712d2f7ac889ba09d635684c7176ec196338316a2d8bb675a375a93c7ddf672b6834d08ac59106bbc83222efe1d76e677075cd3bab51
diff --git a/dev-python/rq/rq-2.3.2.ebuild b/dev-python/rq/rq-2.3.2.ebuild
new file mode 100644
index 0000000000000..b171c55a11d48
--- /dev/null
+++ b/dev-python/rq/rq-2.3.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unnecessary typechecking deps
+	sed -i -e '/types-/d' pyproject.toml || die
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires <sentry-sdk-2
+		tests/test_sentry.py::TestSentry::test_failure_capture
+		# hang
+		tests/test_commands.py::TestCommands::test_shutdown_command
+		tests/test_worker_pool.py::TestWorkerPool::test_check_workers
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}