dev-cpp/edencommon: new package, add 0_pre20220808

Signed-off-by: Sam James <sam@gentoo.org>

dev-cpp/edencommon/Manifest

@@ -0,0 +1 @@
+DIST edencommon-0_pre20220808.tar.gz 142458 BLAKE2B 0dd501069bc511973e89b21b9dbdce7eeb0e87e31ecd05e585fe83c515894691a02e5725de8c912c4bd0fb70f4172445070ef8fec205243e1df9c35a3ccaffe4 SHA512 63f60e1c406d834cf618e2747c21f928e43fe2a475a97152070aecb61b11b5e515bdfd1c9571a93a159d91fa185c9f89caebe8d41421a94e636e8ff43fd11a3a

dev-cpp/edencommon/edencommon-0_pre20220808.ebuild

@@ -0,0 +1,44 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# dev-cpp/edencommon
+# dev-cpp/folly
+# dev-util/watchman
+
+inherit cmake
+
+# No proper tags yet (https://github.com/facebookexperimental/edencommon/issues/2)
+MY_COMMIT="d356bb7a9a28f09f00d72a81f7b60f8f27ce249c"
+DESCRIPTION="Shared library for Watchman and Eden projects"
+HOMEPAGE="https://github.com/facebookexperimental/edencommon"
+SRC_URI="https://github.com/facebookexperimental/edencommon/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${MY_COMMIT}
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="llvm-libunwind"
+
+RDEPEND="
+	dev-cpp/gflags:=
+	dev-cpp/glog:=[gflags]
+	dev-cpp/folly:=
+	llvm-libunwind? ( sys-libs/llvm-libunwind:= )
+	!llvm-libunwind? ( sys-libs/libunwind:= )
+"
+DEPEND="
+	${RDEPEND}
+	dev-cpp/gtest
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+
+	cmake_src_configure
+}

dev-cpp/edencommon/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sam@gentoo.org</email>
+		<name>Sam James</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">facebookexperimental/edencommon</remote-id>
+	</upstream>
+</pkgmetadata>