dev-python/Babel: bump to 2.6.0

Package-Manager: Portage-2.3.42, Repoman-2.3.9

dev-python/Babel/Babel-2.6.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of tools for internationalizing Python applications"
+HOMEPAGE="http://babel.pocoo.org/ https://pypi.org/project/Babel/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc test"
+
+RDEPEND="dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Make the tests use implementation-specific datadir,
+	# because they try to write in it.
+	sed -e '/datadir =/s:os\.path\.dirname(__file__):os.environ["BUILD_DIR"]:' \
+		-i tests/messages/test_frontend.py || die
+	sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x TZ=UTC
+
+	# Create implementation-specific datadir for tests.
+	cp -R -l tests/messages/data "${BUILD_DIR}"/ || die
+	py.test -vv || die
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}

dev-python/Babel/Manifest

@@ -1,2 +1,3 @@
 DIST Babel-2.5.0.tar.gz 6612353 BLAKE2B 85268f0226f1db019fb906da0dfbbc6b6aa199ab491e9d767c932fb5ca77cb6d86328ebaa9c6eb61fb8d28c8e566babd435cdcee9b900c3c680d0dfb49c2bcac SHA512 b24b74121695e0068fb28a6294d4b5b2065e94dcd62ca0d70c8fde3a00cb5ff111480505594460989c6f67a75935f55e153b1b493f917317d2c5ee0f0d7921fc
 DIST Babel-2.5.3.tar.gz 6611941 BLAKE2B 99b71642b00a853fea844220c0ce5ef2fe425906cbdd1618e31f39b60d16382d54ff5e00c493153eee2be8894edc8c96e57fc2703620db5bafcf7b7a4f1b72ef SHA512 1a41f69141da9f66e27110e7a1a5955f76d8ae9353ff7e54182c5bb6ca16e8b4799031e4df1049af54de513da9f101e171e4312b2e7775f2cab9116d5b50c0fb
+DIST Babel-2.6.0.tar.gz 7960433 BLAKE2B 0edc3b3391eb3d479eae9a223668af96e1ec47b84b13d0bb66c0e1772dc5de8321ee06f0d0dfeb6c9364a724286d0ee50a3ab4c2ea789894057fca39bb11dc46 SHA512 a87f26c25f1e48a64d1e7ee112bc0c325a6268e0e716a81cb6814a53f0add8f3d579babd2ba064f160298ebe3ac9711aa5d28f112582ee287767b6ed8427b6e0