diff --git a/dev-python/indexed_gzip/Manifest b/dev-python/indexed_gzip/Manifest
index 336034b66ccbe..a9c5f0491a553 100644
--- a/dev-python/indexed_gzip/Manifest
+++ b/dev-python/indexed_gzip/Manifest
@@ -1 +1,2 @@
+DIST indexed_gzip-1.6.13.tar.gz 102730 BLAKE2B 8ab5490c3c830121ce3104c624fe36cb0064f6265b5e5f9ebd6efb0402c33e206b4d97c35803fa10fdbc25a7ccac61f19b2fd9bfb205e07acee40737d6404659 SHA512 de8a606f712a0bddf618cedac12d2b5613e14aaaacc93d1930352101bdeaca8bd5126dd67df36d691f31bc27d553a61901934bbb0b2514e4360c6cd49e395c41
 DIST indexed_gzip-1.6.4.tar.gz 101683 BLAKE2B 01d34b33f8d6a623f92bd3f6751303b32f3834e9fb7849b13b82080eeaa91bb29fa38e45287256b6946ecafae7fd000f0cd12f004662eb2e5ad9f31be7378505 SHA512 b7b804c99c560f939a165fdd6d4b881fab2dd2664cecf88f9d9dba46c389efa4839dfbffd19a1a30b801e2fde43580279ea2adab5fd0bbb379ad77c568f8d6b9
diff --git a/dev-python/indexed_gzip/indexed_gzip-1.6.13.ebuild b/dev-python/indexed_gzip/indexed_gzip-1.6.13.ebuild
new file mode 100644
index 0000000000000..71ce12536dee6
--- /dev/null
+++ b/dev-python/indexed_gzip/indexed_gzip-1.6.13.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Fast random access of gzip files in Python"
+HOMEPAGE="
+	https://pypi.org/project/indexed-gzip/
+	https://github.com/pauldmccarthy/indexed_gzip/
+"
+SRC_URI="
+	https://github.com/pauldmccarthy/indexed_gzip/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	sys-libs/zlib:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_compile() {
+	if use test; then
+		export INDEXED_GZIP_TESTING=1
+	fi
+	distutils-r1_src_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)/indexed_gzip/tests" || die
+	epytest
+}
diff --git a/dev-python/indexed_gzip/metadata.xml b/dev-python/indexed_gzip/metadata.xml
index bc43b287423a4..a452ad470e8d1 100644
--- a/dev-python/indexed_gzip/metadata.xml
+++ b/dev-python/indexed_gzip/metadata.xml
@@ -21,7 +21,7 @@
 		compression standard), but will work with any GZIP file.
 	</longdescription>
 	<upstream>
-		<remote-id type="github">pauldmccarthy/indexed_gzip</remote-id>
+		<remote-id type="github">pauldmccarthy/indexed-gzip</remote-id>
 		<remote-id type="pypi">indexed-gzip</remote-id>
 	</upstream>
 </pkgmetadata>