From c98400eb26c73cdbb9571ce20d4c82ade5ec77c9 Mon Sep 17 00:00:00 2001
From: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Date: Sat, 2 May 2026 15:53:11 +0200
Subject: [PATCH] sci-astronomy/siril: add 1.4.2

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Part-of: https://github.com/gentoo/gentoo/pull/46184
Closes: https://github.com/gentoo/gentoo/pull/46184
Signed-off-by: Sam James <sam@gentoo.org>
---
 sci-astronomy/siril/Manifest           |   1 +
 sci-astronomy/siril/siril-1.4.2.ebuild | 106 +++++++++++++++++++++++++
 2 files changed, 107 insertions(+)
 create mode 100644 sci-astronomy/siril/siril-1.4.2.ebuild

diff --git a/sci-astronomy/siril/Manifest b/sci-astronomy/siril/Manifest
index 26a6b7eaac195..97918bb34f840 100644
--- a/sci-astronomy/siril/Manifest
+++ b/sci-astronomy/siril/Manifest
@@ -1,2 +1,3 @@
 DIST siril-1.2.6.tar.bz2 4621526 BLAKE2B b0d2b69ac601a28f033c2b02eda8a418aba1bdbacb9f1abe52b69a4a133808e3c176274da5fb7e025aff558243e9a187d77dbecad302d4b437e4fc3b33483934 SHA512 bf1503a9759e08c2767dc267860d129be7ce345695db0c89a4bf199775c084f77e10f2675e9491074f21022dcbdd3fdb161be5d541405c18c25a758226703009
 DIST siril-1.4.0.tar.bz2 14754666 BLAKE2B 8893fcaceb4263ade09e3e0e9063750845fbebb53ad9c8aa64b0254e2233ff9936132ea2cdd1f050dd42857418a0278d03013e55a9defb2227a555738011b1c6 SHA512 79655cf6110793452efac30d3be2b620e5ae4ba4fa53c88855d162f930df3980284dff1c17895f26922f4213be5cfc860bef67bc799f3eece1be87a2a1c1960a
+DIST siril-1.4.2.tar.bz2 14805286 BLAKE2B 493f98a3200aa9fb62b5661cbfbcf15faf5920f087b21f24eeef11a726a966ba56bfc554a8499c0bcdad9e042129a6d882b424564c181fb42adf74b6315fd3c7 SHA512 8b0ef74cd517972cc665c93c44d525ff467c07f28ee316b1ff9376a5a63248c6aa2cdfe48e3add37917489e8cee7995c5737dbe09f69869c3af73c80a9c2578c
diff --git a/sci-astronomy/siril/siril-1.4.2.ebuild b/sci-astronomy/siril/siril-1.4.2.ebuild
new file mode 100644
index 0000000000000..0194ed3700adc
--- /dev/null
+++ b/sci-astronomy/siril/siril-1.4.2.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+PYTHON_REQ_USE="tk"
+
+inherit meson python-r1 toolchain-funcs xdg
+
+DESCRIPTION="A free astronomical image processing software"
+HOMEPAGE="https://siril.org/"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+LICENSE="GPL-3+ Boost-1.0"
+SLOT="0"
+IUSE="curl exif ffmpeg git heif jpeg jpegxl openmp png raw tiff"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/yyjson-0.10.0:=
+	media-libs/lcms:=
+	media-libs/librtprocess
+	>=media-libs/opencv-4.2.0:=[features2d]
+	>=sci-astronomy/wcslib-7.12:=
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22.0:3
+	x11-libs/gtksourceview:4
+	x11-libs/pango
+	virtual/zlib:=
+	curl? ( net-misc/curl )
+	exif? ( >=media-gfx/exiv2-0.25:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	git? ( dev-libs/libgit2:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( >=media-libs/libpng-1.6.0:= )
+	raw? ( media-libs/libraw:= )
+	tiff? ( media-libs/tiff:= )
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-build/cmake
+	x11-base/xorg-proto
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.4-docfiles.patch"
+)
+
+DOCS=( README.md ChangeLog AUTHORS )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local emesonargs=(
+		-DlibXISF=false
+		-Dffms2=false
+		-Dcriterion=false
+		$(meson_use curl libcurl)
+		$(meson_use exif exiv2)
+		$(meson_use ffmpeg)
+		$(meson_use git libgit2)
+		$(meson_use heif libheif)
+		$(meson_use jpeg libjpeg)
+		$(meson_use jpegxl libjxl)
+		$(meson_use openmp)
+		$(meson_use png libpng)
+		$(meson_use raw libraw)
+		$(meson_use tiff libtiff)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}