diff --git a/dev-util/gtk-doc/Manifest b/dev-util/gtk-doc/Manifest
index ca58663a6510b..b9945c4e60808 100644
--- a/dev-util/gtk-doc/Manifest
+++ b/dev-util/gtk-doc/Manifest
@@ -1 +1,2 @@
 DIST gtk-doc-1.34.0.tar.xz 494116 BLAKE2B cb8550debed9f32b967de9d4ebdde8dbe83551eb8527221d2d788355431f34e62a4beedda3e7f5722516ae8e23794a56b97a4f761ede0f7f2c0ef288624b5f7a SHA512 d962fe31949b5f7c70122c7ebbd98f4d21725697804bf5dd75fd7a6662753a91c9350fd1e8bed22a58a957b173f35e200fcbb4c7c2ebc45ccbc0db2e916b27ea
+DIST gtk-doc-1.36.1.tar.xz 594020 BLAKE2B a566461c4c9bb8f072b8f6b92c917d5ec7da33f0f7a3893a89e85d830a9430e37ae68817d1a5c7bc2cab9000c0e4938da5b456bdf615144cba8a4b65d419b934 SHA512 20caee6904220785369e768a2dfa73f52e8a0f0672e44dab9553888c6755e92a5a5bae6d659a445c80935fc3a368f3f82111baeb8546c33ad95bcfd1e00d117f
diff --git a/dev-util/gtk-doc/gtk-doc-1.36.1.ebuild b/dev-util/gtk-doc/gtk-doc-1.36.1.ebuild
new file mode 100644
index 0000000000000..8c562bac4f65a
--- /dev/null
+++ b/dev-util/gtk-doc/gtk-doc-1.36.1.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit elisp-common gnome.org meson python-single-r1 readme.gentoo-r1
+
+DESCRIPTION="GTK+ Documentation Generator"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gtk-doc"
+
+LICENSE="GPL-2+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-solaris"
+
+IUSE="emacs test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.68:2
+	dev-libs/libxslt
+	>=dev-libs/libxml2-2.3.6:2=
+	~app-text/docbook-xml-dtd-4.3
+	app-text/docbook-xsl-stylesheets
+	~app-text/docbook-sgml-dtd-3.0
+	>=app-text/docbook-dsssl-stylesheets-1.40
+	emacs? ( >=app-editors/emacs-23.1:* )
+	$(python_gen_cond_dep '
+		dev-python/pygments[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/parameterized[${PYTHON_USEDEP}]
+		')
+	)
+"
+BDEPEND="
+	test? ( dev-python/parameterized  )
+	~dev-build/gtk-doc-am-${PV}
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Remove global Emacs keybindings, bug #184588
+	"${FILESDIR}"/${PN}-1.8-emacs-keybindings.patch
+)
+
+pkg_setup() {
+	DOC_CONTENTS="gtk-doc does no longer define global key bindings for Emacs.
+		You may set your own key bindings for \"gtk-doc-insert\" and
+		\"gtk-doc-insert-section\" in your ~/.emacs file."
+	SITEFILE=61${PN}-gentoo.el
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Requires the unpackaged Python "anytree" module
+	sed -i -e '/mkhtml2/d' "${S}"/tests/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dautotools_support=true
+		-Dcmake_support=true
+		-Dyelp_manual=true
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	use emacs && elisp-compile tools/gtk-doc.el
+}
+
+src_install() {
+	meson_src_install
+
+	# The meson build system configures the shebangs to the temporary python
+	# used during the build. We need to fix it.
+	sed -i -e 's:^#!.*python3:#!/usr/bin/env python3:' "${ED}"/usr/bin/* || die
+	python_fix_shebang "${ED}"/usr/bin
+
+	# Don't install this file, it's in gtk-doc-am now
+	rm "${ED}"/usr/share/aclocal/gtk-doc.m4 || die "failed to remove gtk-doc.m4"
+	rmdir "${ED}"/usr/share/aclocal || die
+
+	if use emacs; then
+		elisp-install ${PN} tools/gtk-doc.el*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		readme.gentoo_create_doc
+	fi
+}
+
+pkg_postinst() {
+	if use emacs; then
+		elisp-site-regen
+		readme.gentoo_print_elog
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}