sci-libs/pdal: bump v2.9.1

Signed-off-by: Thomas Bettler <thomas.bettler@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/43585
Closes: https://github.com/gentoo/gentoo/pull/43585
Signed-off-by: Sam James <sam@gentoo.org>

sci-libs/pdal/Manifest

@@ -1,3 +1,4 @@
 DIST PDAL-2.8.2-src.tar.bz2 87504277 BLAKE2B b2037a4fe5ac369380d2b2d83a2210a3c17757f9e6f749e819854d7356ba07d85b83fe3221ab9024f40f8a9f0ec6ee86573092914ac633af56b361a2f128cb00 SHA512 82dc84192e0cda809f4b12233e009c0c92328bf78001fc6394f56b28514a4b20de17dd354904d44cebc40c28a78828c47a1324b749143cc5b41b6c322902a442
 DIST PDAL-2.8.4-src.tar.bz2 86725389 BLAKE2B f1f1009be5d0655f33fe6c57f1efe0f878bb2a2de2075a3d18b2e64d4a07d5201857a78b13288365b9110e106022a473cf7793e1ac2c744499ba0752c67bd0c3 SHA512 5d754d6fa656615aa4a9dc31ca5d5c051194148d721ce217ca4b8a87af54889717b8470b789899e486e0ed3154906659b0c336ed7571abddda0a182febf37e6b
 DIST PDAL-2.9.0-src.tar.bz2 96938361 BLAKE2B f47780f7ccd840099844cadb90e38e8fe8007f35e135f96adccbbffce0647f9599c3c02494c3dd0457a2e82b22e5c38c472f36b5a3a8cca42e3ff6448440ed53 SHA512 1ff1dcfdca261968a5e20ce9072181a687430e9ef5601d7f15c12cbf1af1696cd84c991bcad67e4c7cdfe279b66d12a0bc06016cee5a4106331b12eb6aa8a7a4
+DIST PDAL-2.9.1-src.tar.bz2 97147474 BLAKE2B 56bd688efec43076cbcbf58c44c5b35b283ba408280e1cee6cbff5eac36b5567363762569ac29260ab96be6bdcc07d1f66bfa8475c09d506983b62e65465a0cc SHA512 138d85a866343cb48024e417e65d6bed05f7600419545c4fc8ccdc7dc28af94b9beda18a700d88b5fef012e220a92b029aa88562ac9e5c3aad0504e676e2fb36

sci-libs/pdal/pdal-2.9.1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A C++ library for translating and manipulating point cloud data"
+HOMEPAGE="https://pdal.io/"
+SRC_URI="https://github.com/PDAL/PDAL/releases/download/${PV}/PDAL-${PV}-src.tar.bz2"
+S="${WORKDIR}/PDAL-${PV}-src"
+
+LICENSE="BSD"
+SLOT="0/19"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="debug postgres test"
+
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( >=dev-cpp/gtest-1.15.0 )
+"
+RDEPEND="
+	net-misc/curl
+	app-arch/zstd:=
+	dev-libs/libxml2
+	dev-libs/openssl:=
+	sci-libs/gdal:=
+	>=sci-libs/libgeotiff-1.7.0:=
+	sys-libs/zlib
+	debug? ( sys-libs/libunwind:= )
+	postgres? ( dev-db/postgresql:*[xml] )
+"
+
+DEPEND="
+	test? ( sci-libs/gdal[geos,jpeg,png,sqlite] )
+	${RDEPEND}
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLUGIN_PGPOINTCLOUD="$(usex postgres)"
+		-DWITH_COMPLETION=ON
+		-DWITH_BACKTRACE="$(usex debug)"
+		-DWITH_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		--exclude-regex '(pgpointcloudtest|pdal_info_test|pdal_io_bpf_base_test|pdal_io_bpf_zlib_test|pdal_filters_overlay_test|pdal_filters_stats_test|pdal_app_plugin_test|pdal_merge_test|pdal_io_stac_reader_test)'
+		--output-on-failure
+		-j1
+	)
+
+	cmake_src_test
+}