gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 02:17:34 -08:00
Code Issues Projects Releases Wiki Activity

net-irc/irssi: use PERL_FEATURES

Browse Source 
The ebuild uses GENTOO_DEPEND_ON_PERL=no because Perl is optional
in irssi, so we have to do it "manually", but it's not so bad as we
can just use the variables the eclass provides.

Bug: https://bugs.gentoo.org/144256
Bug: https://bugs.gentoo.org/616176
Bug: https://bugs.gentoo.org/674596
Bug: https://bugs.gentoo.org/875101
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James 2025-09-19 16:23:18 +01:00
parent 00726edddd
commit c80b6e5a94
No known key found for this signature in database
GPG Key ID: 738409F520DF9190
2 changed files with 77 additions and 3 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

71
net-irc/irssi/irssi-1.4.5-r1.ebuild Normal file
View File

@ -0,0 +1,71 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GENTOO_DEPEND_ON_PERL="no"
inherit perl-module meson
DESCRIPTION="A modular textUI IRC client with IPv6 support"
HOMEPAGE="https://irssi.org/"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
inherit git-r3
else
# Keep for _rc compability
MY_P="${P/_/-}"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${MY_P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="otr +perl selinux +proxy ${GENTOO_PERL_USESTRING}"
RDEPEND="
>=dev-libs/glib-2.6.0
dev-libs/openssl:=
sys-libs/ncurses:=
otr? (
>=dev-libs/libgcrypt-1.2.0:=
>=net-libs/libotr-4.1.0
)
perl? (
${GENTOO_PERL_DEPSTRING}
dev-lang/perl:=
)
"
DEPEND="${RDEPEND}"
BDEPEND="dev-lang/perl
virtual/pkgconfig"
RDEPEND+=" selinux? ( sec-policy/selinux-irc )"
src_configure() {
local emesonargs=(
-Ddocdir="${EPREFIX}"/usr/share/doc/${PF}
-Dwith-perl-lib=vendor
-Dwith-otr=$(usex otr)
-Dwith-proxy=$(usex proxy)
-Dwith-perl=$(usex perl)
# Carried over from autotools (for now?), bug #677804
-Ddisable-utf8proc=yes
-Dwith-fuzzer=no
-Dinstall-glib=no
)
meson_src_configure
}
src_test() {
# We don't want perl-module's src_test
meson_src_test
}
src_install() {
meson_src_install
use perl && perl_delete_localpod
}

9
net-irc/irssi/irssi-9999.ebuild
View File

@ -1,4 +1,4 @@
# Copyright 1999-2023 Gentoo Authors
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@ -22,7 +22,7 @@ fi
LICENSE="GPL-2"
SLOT="0"
IUSE="otr +perl selinux +proxy"
IUSE="otr +perl selinux +proxy ${GENTOO_PERL_USESTRING}"
RDEPEND="
>=dev-libs/glib-2.6.0
@ -32,7 +32,10 @@ RDEPEND="
>=dev-libs/libgcrypt-1.2.0:=
>=net-libs/libotr-4.1.0
)
perl? ( dev-lang/perl:= )
perl? (
${GENTOO_PERL_DEPSTRING}
dev-lang/perl:=
)
"
DEPEND="${RDEPEND}"
BDEPEND="dev-lang/perl