From c6ab3b3d3c899fc8fbb6e13595f153e551c88948 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 10 Apr 2022 09:51:52 +0200
Subject: [PATCH] dev-python/ruamel-std-pathlib: Remove namespace dep
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../ruamel-std-pathlib-0.9.2-r1.ebuild        | 40 +++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild

diff --git a/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild b/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild
new file mode 100644
index 0000000000000..7ebe0572a78b5
--- /dev/null
+++ b/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+MY_P="${PN//-/.}-${PV}"
+DESCRIPTION="Ruamel enhancements to pathlib and pathlib2"
+HOMEPAGE="
+	https://pypi.org/project/ruamel.std.pathlib/
+	https://sourceforge.net/projects/ruamel-std-pathlib/
+"
+# PyPI tarballs do not include tests
+SRC_URI="mirror://sourceforge/ruamel-dl-tagged-releases/${MY_P}.tar.xz -> ${P}.tar.xz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	# this is needed to keep the tests working while
+	# dev-python/namespace-ruamel is still installed
+	cat > "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py <<-EOF || die
+		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
+	EOF
+	epytest
+	rm "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py || die
+}