diff --git a/dev-python/elastic-transport/Manifest b/dev-python/elastic-transport/Manifest
new file mode 100644
index 0000000000000..e073f70eadc66
--- /dev/null
+++ b/dev-python/elastic-transport/Manifest
@@ -0,0 +1 @@
+DIST elastic-transport-8.4.0.gh.tar.gz 70975 BLAKE2B cec717606a55906da9157a0aaa3c656041201c2b62c77d42a67aabaad387c2e9f139dd1bd39e31b15f51fa2ac1b605d9f98b540000ee03d8aecf118cf972048a SHA512 82d0e0af3992335ce17bdc2a74f80fbf98bc9873d798be65f30d59fa55cb3bf50b55821133ea01d2ced9c27bf4019bac19e76e6853c29b87762ae0a9b593c3f5
diff --git a/dev-python/elastic-transport/elastic-transport-8.4.0.ebuild b/dev-python/elastic-transport/elastic-transport-8.4.0.ebuild
new file mode 100644
index 0000000000000..c2beee2e25d7a
--- /dev/null
+++ b/dev-python/elastic-transport/elastic-transport-8.4.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1
+
+DESCRIPTION="Transport classes and utilities shared among Python Elastic client libraries"
+HOMEPAGE="
+	https://github.com/elastic/elastic-transport-python
+	https://pypi.org/project/elastic-transport/
+"
+SRC_URI="https://github.com/elastic/elastic-transport-python/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-python-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.2[${PYTHON_USEDEP}] <dev-python/urllib3-2[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		  ${RDEPEND}
+		  dev-python/aiohttp[${PYTHON_USEDEP}]
+		  dev-python/mock[${PYTHON_USEDEP}]
+		  dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		  dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		  dev-python/pytest-mock[${PYTHON_USEDEP}]
+		  dev-python/requests[${PYTHON_USEDEP}]
+		  dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx dev-python/furo dev-python/sphinx-autodoc-typehints
+distutils_enable_tests pytest
+
+src_prepare() {
+	# Remove extra options from tests. Mainly to avoid dependance on coverage
+	sed -i '/[tool:pytest]/,/^$/ d' setup.cfg || die
+	# Pytest options add more warnings and individually ingoring warnings would be more hassle than worth
+	# So lets just remove the bit counting warnings, as the test checks if there is a specific warning eitherway.
+	sed -i '/test_uses_https_if_verify_certs_is_off/,/def/ { /assert 1 == len(w)/ d }' \
+		tests/node/test_http_aiohttp.py || die
+
+	default
+}
diff --git a/dev-python/elastic-transport/metadata.xml b/dev-python/elastic-transport/metadata.xml
new file mode 100644
index 0000000000000..a37877aad1858
--- /dev/null
+++ b/dev-python/elastic-transport/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person" proxied="yes">
+    <email>parona@protonmail.com</email>
+    <name>Alfred Wingate</name>
+  </maintainer>
+  <maintainer type="project" proxied="proxy">
+    <email>proxy-maint@gentoo.org</email>
+    <name>Proxy Maintainers</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">elastic/elastic-transport-python</remote-id>
+    <remote-id type="pypi">elastic-transport</remote-id>
+  </upstream>
+</pkgmetadata>