dev-python/zc-lockfile: Basic inter-process locks

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: William Hubbs <williamh@gentoo.org>

dev-python/zc-lockfile/Manifest

@@ -0,0 +1 @@
+DIST zc.lockfile-1.4.tar.gz 11075 BLAKE2B 4fcc18b4d337c1b102916588aef7271fe189f30e442b5d2180b5a20d804f84649d4bf9dc6f601e6b7ee38c4a436c3848b83cbcb1a19974acdf072347b6822b83 SHA512 f145c34088770b50002d1caa88876f9fb11f3b9810fe68b8e1a38d27084d27ce058883228469abb05811f3f11a7b94acdaad8392eb1b6c34c98ddc885cdf77be

dev-python/zc-lockfile/metadata.xml

@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>williamh@gentoo.org</email>
+		<name>William Hubbs</name>
+	</maintainer>
+</pkgmetadata>

dev-python/zc-lockfile/zc-lockfile-1.4.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Basic inter-process locks"
+HOMEPAGE="https://pypi.org/project/zc.lockfile/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND=">=dev-python/setuptools-3.3[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}"/${MY_P}
+
+DOCS=( CHANGES.rst README.rst )
+
+# Prevent incorrect installation of data file
+python_prepare_all() {
+	sed -e '/^    include_package_data/d' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" src/zc/lockfile/tests.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	python_moduleinto zc
+	python_domodule src/zc/__init__.py
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	find "${D}" -name '*.pth' -delete || die
+}