diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index a089ad67ca9b9..50032d7b1e777 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -7,3 +7,4 @@ DIST hypothesis-6.104.1.gh.tar.gz 9466716 BLAKE2B 5ddefd5199bfb22ef8c2c2ae995de5
 DIST hypothesis-6.104.2.gh.tar.gz 9467131 BLAKE2B 22be74426808bef091351cfb688bdb1fa8ce84f011d3303e7455526f38732bba44c9d82a8162d12e395a192a644f188e7991f7311bebb676c28197131b272a19 SHA512 18b11669bc1d2ba6e7ef0854823c22798fa86e988d951a223235160460fb79b5a5d10caf8fc7aa06ba5996c75ff7e8146725bf1ed3b9b4e169f93cbfa0bf2776
 DIST hypothesis-6.105.0.gh.tar.gz 9467572 BLAKE2B be878220e5908ca8b20c6b6ed8ab61638e2a5605118b61ecb715b94353751d014644995e8ab6056e2e5b4cab94e533117de199997bd3492b78465694321e4afa SHA512 dd6284ed12b68b9ff7fcb3026f08de240959f116b7444384c1737ef632483796ef3f1687796fa744d8cd7855811916a070ff48d66dc8ace869ee24d9ee9d8ca3
 DIST hypothesis-6.105.1.gh.tar.gz 9468095 BLAKE2B 285a6291ad1386384afa08634a2d7b4802060514e22a7f78d42a1cf97e548a4da6abffd24c98a931a07db9779ed5c54514e5460393ab12a904c5054db2bbb038 SHA512 f3a900d566a00ec178de3550108b752c70819b1081c0b3dcbe05aaee43cafb62f11d90efb6718d19039c2cb87ac55255dff09a71dafb7d6203f76408788e5cdf
+DIST hypothesis-6.106.0.gh.tar.gz 9469265 BLAKE2B ece6e47c8b8927bc9d4a470b14a8546abc506d6f50ecf33a83429aafcc31115dbad71d9f7ff07f60cc100a9ca26aabf111c86e1afd6882be2ccc00dcbfe3648f SHA512 3ae6e874a032ddc53fb6d609c49e3942ae121c0ef3e4dee5303fd52002379b86a5a5471fae229e646fccb44d71cc5f98159843d411deef702237bcfb6343b676
diff --git a/dev-python/hypothesis/hypothesis-6.106.0.ebuild b/dev-python/hypothesis/hypothesis-6.106.0.ebuild
new file mode 100644
index 0000000000000..d401f55b27881
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.106.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${CLI_COMPAT[@]}" )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}