diff --git a/dev-python/characteristic/characteristic-14.3.0-r1.ebuild b/dev-python/characteristic/characteristic-14.3.0-r1.ebuild
new file mode 100644
index 0000000000000..32358868a9dd1
--- /dev/null
+++ b/dev-python/characteristic/characteristic-14.3.0-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Python attributes without the boilerplate"
+HOMEPAGE="https://characteristic.readthedocs.org/ https://github.com/hynek/characteristic"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}