diff --git a/dev-dotnet/dotnet-sdk-bin/Manifest b/dev-dotnet/dotnet-sdk-bin/Manifest
index 1a81adadd33ab..f32a6a778e558 100644
--- a/dev-dotnet/dotnet-sdk-bin/Manifest
+++ b/dev-dotnet/dotnet-sdk-bin/Manifest
@@ -10,6 +10,12 @@ DIST dotnet-sdk-10.0.102-linux-musl-arm.tar.gz 233409839 BLAKE2B ea59338fa8cb3a9
 DIST dotnet-sdk-10.0.102-linux-musl-arm64.tar.gz 232690413 BLAKE2B 786d052619a423adea2221e612fef6df20a1c05caa044fce16183486f2e024ad22f5a9eda6e68fbd79b0c296428094554c8365606470fe4cd54000fb01701b81 SHA512 10be1f3f2516fbc1049ad8fcb00bd12bbb16a2d20f708b6cd0177cd8775d01e9dec10ec1fbe4b570d7c82b158cb745d77e8ec66ff0b9f56327778562ba1a77be
 DIST dotnet-sdk-10.0.102-linux-musl-x64.tar.gz 240080363 BLAKE2B 6a1349fdfdba8a0a84ad8cc45013c8b3d2280844574cfb1288769c245f3e934781c3473df7cddf752732c62481c75ce989701ef38c50e6ea817896a10cd40fd9 SHA512 3586eb8de224d7585bf6cfd20f489e27c0a2a1fc8cb107c7ee2a07bead48b1edb0241f52febcf0e2f9f5fdf3ece3cf2e2f988b149166947445189e7406652ccd
 DIST dotnet-sdk-10.0.102-linux-x64.tar.gz 240084834 BLAKE2B b40cca6080cfd53068fa7a598a64f55f613b2a4567671958c3bd93d2233a7dadb7372370d9ba1cac35a9a33f44985aea4f42a02902044723e3d98128d0bb21eb SHA512 7adf40e8e5547970391cfbe474c3874c6918ce3575ac398f376c78502134e1c8a2fa3da9aca281fdaeda81671f56c851ebe9e74c5b57c5a298bd45deba63565d
+DIST dotnet-sdk-10.0.103-linux-arm.tar.gz 233420417 BLAKE2B 9cbdec865da20bc345dc503041d9ee1973eef479e0d1d550ad18ddb83549d718bc1b25ece51263eff86b85eec4b69fa2e35f08bfcc2e73ab9ba7368ea037d2d0 SHA512 c6eb59781abc7b27d723c735de867a7db7052df8e95739b42a7f4bfde7a97d16777cb2179a4922955f70fa3f6dfca05c11cd91babd76f6904f84967d9be0ff25
+DIST dotnet-sdk-10.0.103-linux-arm64.tar.gz 232654429 BLAKE2B 2baf20e4565934b5be33c01db978f9daf0960eb5eb5e5baae7503338ad0b2496bb97520e3be97f976d865f33d1167fb7aa1e2890af379779d3ebaede4df1287e SHA512 ab45b6baeae956e4465151787d8b8113b66679ed55da1e72c57e99aa5ab8f42471e80dc8a5fd22c31df74e60446a3b252d2900658cefc9506fcb0da7e2831e21
+DIST dotnet-sdk-10.0.103-linux-musl-arm.tar.gz 233495912 BLAKE2B 7ab9f539a6fda0b4864776c643e23705800d75c39e0b3de21948420a80796c97d141ea29705f6dc6e8b4d2bfd8d859e36d785af685d27a5912793dc2d869f992 SHA512 6fee1341fedb60dd8d240c97de36b7308782b57f5b3256910a1a98bb1bfc7472848fc0c192ddb9a5c95d733680ad6d9d74139f11a8afb3c442d2f7a6e8b84c77
+DIST dotnet-sdk-10.0.103-linux-musl-arm64.tar.gz 232770769 BLAKE2B 8db278ab3aca0011c847248047c01f9d24587a11dd880079be21df7c8629e20e5fa655e884681101059e4128bce08a514904693c4213b520afc2cc5d8d135b27 SHA512 905fd3a0d53193de10b4b0bd2eef05adda22ad4090cae335f7bbf064e33ca23a754855ec7f2db61703abacf142fbb9f3fb27e1a6fe69eef1f8186fa0fd96ee28
+DIST dotnet-sdk-10.0.103-linux-musl-x64.tar.gz 240366677 BLAKE2B e4999fd9a230247bb157fcecdd64d8f39be0297cd9adfcb4498d139b574e8eeb76dbfbd887e6072504e4c29dcd07e27c36175c4620b72d503cd026adcaa3854d SHA512 fccb361461d8bf30bfef01d3c69cffaeea9f13724f48805a6ac5a39e9c7de67141b3f9302ccf4c79e3a441c9bda3d4b92ea84817f8d155cfd912f9357c291d6e
+DIST dotnet-sdk-10.0.103-linux-x64.tar.gz 240189641 BLAKE2B f7030fe9633e710e780be5a9b1b04c9c8a55d69026dee935fd7b61da65094475ed37da4f809228a999bcf2d9ae8859d715bc66859eec1f3b019a2536d5d33df1 SHA512 bab94f13c57b2ac821d4924fe66084be9b44c41761ff7ff64522c8f7aba345659d31258401dcec31cc3cf6ccae1d012623075aca1c9b9165bcfe5ba9abda1c0c
 DIST dotnet-sdk-6.0.417-linux-arm.tar.gz 182268907 BLAKE2B fef6b9845d6ba6fd19cbe580f3a868ad48872fc919d119123886a9c975281ed0ab407cfe24421da1fb6bc6cc907c3d693278e0a3ab05f4382c10203095710c6e SHA512 f14d5d24d6611139cff313275599923856307c3afe57d2439eb95e2a89da5fb54fdb6ce5b0d7a243f2d031af4eb0c277ce1914725f8b9dcff4002fcc05489f08
 DIST dotnet-sdk-6.0.417-linux-arm64.tar.gz 179979647 BLAKE2B 069d6afc216b6ed3ebe3093e933f88af4d51f6a994fc4aeaae85658583a5cabf5e8ab08a0e1cfe53f7f19743769a9183b9e3d64b5464d6d96288ba51d983f261 SHA512 39cada75d9b92797de304987437498d853e1a525b38fa72d0d2949932a092fcf6036b055678686db42682b5b79cdc5ec5995cb01aa186762e081eb1ed38d2364
 DIST dotnet-sdk-6.0.417-linux-musl-arm.tar.gz 182168816 BLAKE2B b5e149074cb6076e03aaa90545d3916c072e9d1c46f6831633786658424fb8cbf12e72c3f497cb49755696668acb027534606152514f09d3417336aa7eb44eab SHA512 86bff3ab8cecfd16f3d9d26da87b6cbeffd2041d474c56602ee5d77f6883fa64cfe85a19291fdc5afaab438fa5871e366f754b211ece161887f53c637473b661
diff --git a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-10.0.103.ebuild b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-10.0.103.ebuild
new file mode 100644
index 0000000000000..c499ee5a0a98d
--- /dev/null
+++ b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-10.0.103.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+SDK_SLOT="$(ver_cut 1-2)"
+RUNTIME_SLOT="${SDK_SLOT}.3"
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/
+	https://github.com/dotnet/dotnet/"
+SRC_URI="
+amd64? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz
+	)
+)
+arm? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz
+	)
+)
+arm64? (
+	elibc_glibc? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz
+	)
+	elibc_musl? (
+		https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz
+	)
+)
+"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
+# See bug https://bugs.gentoo.org/932377
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
+# bug https://bugs.gentoo.org/923430
+RESTRICT="splitdebug strip"
+
+CURRENT_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
+"
+EXTRA_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-6.0.36
+	~dev-dotnet/dotnet-runtime-nugets-7.0.20
+	~dev-dotnet/dotnet-runtime-nugets-8.0.24
+	~dev-dotnet/dotnet-runtime-nugets-9.0.13
+"
+NUGETS_DEPEND="
+	${CURRENT_NUGETS_DEPEND}
+	${EXTRA_NUGETS_DEPEND}
+"
+
+RDEPEND="
+	app-crypt/mit-krb5:0/0
+	dev-libs/icu
+	|| (
+		dev-util/lttng-ust-compat:0/2.12
+		dev-util/lttng-ust:0/2.12
+	)
+	virtual/zlib:0/1
+"
+BDEPEND="
+	dev-util/patchelf
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+PDEPEND="
+	${NUGETS_DEPEND}
+"
+
+QA_PREBUILT="*"
+
+MUSL_BAD_LINKS=(
+	apphost
+	createdump
+	dotnet
+	libSystem.Globalization.Native.so
+	libSystem.IO.Compression.Native.so
+	libSystem.Native.so
+	libSystem.Net.Security.Native.so
+	libSystem.Security.Cryptography.Native.OpenSsl.so
+	libclrgc.so
+	libclrjit.so
+	libcoreclr.so
+	libcoreclrtraceptprovider.so
+	libdbgshim.so
+	libhostfxr.so
+	libhostpolicy.so
+	libmscordaccore.so
+	libmscordbi.so
+	libnethost.so
+	singlefilehost
+)
+MUSL_BAD_SONAMES=(
+	libc.musl-aarch64.so.1
+	libc.musl-armv7.so.1
+	libc.musl-x86_64.so.1
+)
+
+src_prepare() {
+	default
+
+	# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
+	if use elibc_musl ; then
+		local musl_bad_link
+		local musl_bad_link_path
+		local musl_bad_soname
+
+		for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
+			while read -r musl_bad_link_path ; do
+				# Skip if file either does not end with ".so" or is not executable.
+				# Using "case" here for easier matching in case we have to add
+				# a special exception.
+				case "${musl_bad_link_path}" in
+					*.so )
+						:
+						;;
+					* )
+						if [[ ! -x "${musl_bad_link_path}" ]] ; then
+							continue
+						fi
+						;;
+				esac
+
+				einfo "Fixing musl libc link for ${musl_bad_link_path}"
+
+				for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
+					patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
+				done
+
+				patchelf --add-needed libc.so "${musl_bad_link_path}" || die
+			done < <(find . -type f -name "${musl_bad_link}")
+		done
+	fi
+
+	# Remove static libraries, bug https://bugs.gentoo.org/825774
+	find ./packs -type f -name "libnethost.a" -delete || die
+}
+
+src_install() {
+	local dest="opt/${PN}-${SDK_SLOT}"
+	dodir "${dest%/*}"
+
+	# Create a magic workloads file, bug #841896
+	local featureband="$(( $(ver_cut 3) / 100 * 100 ))"       # e.g. 404 -> 400
+	local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
+
+	mkdir -p "${S}/${workloads}" || die
+	touch "${S}/${workloads}/userlocal" || die
+
+	mv "${S}" "${ED}/${dest}" || die
+	mkdir "${S}" || die
+
+	fperms 0755 "/${dest}"
+	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}