From be36e48564cd644c58124fa92e4414c20446ef21 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Ulrich=20M=C3=BCller?= <ulm@gentoo.org>
Date: Sun, 31 May 2026 16:43:11 +0200
Subject: [PATCH] app-xemacs/ebuild-mode: add 1.83
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-xemacs/ebuild-mode/Manifest               |  1 +
 .../ebuild-mode/ebuild-mode-1.83.ebuild       | 62 +++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 app-xemacs/ebuild-mode/ebuild-mode-1.83.ebuild

diff --git a/app-xemacs/ebuild-mode/Manifest b/app-xemacs/ebuild-mode/Manifest
index 3e90fec864fe6..ad9951b36753c 100644
--- a/app-xemacs/ebuild-mode/Manifest
+++ b/app-xemacs/ebuild-mode/Manifest
@@ -1,2 +1,3 @@
 DIST ebuild-mode-1.81.tar.xz 52380 BLAKE2B b088e0e40e73c3eb1d8b0584a13e581cda1f1e7fc65050c0a1dd3e25fa81baf554efbf8719e5987794387d4a85c7a012bef50e9dbc109cdf4b3cddc9c7d65035 SHA512 3817f99037a4f143a5016c0bb8f895bc96e3330dd3eb698bbaf65767bcebcb6a06edc3f769dc6abef59296ec13e1e2f8d637deb390120b008d273992f2e840d1
 DIST ebuild-mode-1.82.tar.xz 51824 BLAKE2B 0afd22fd50519a292f80b0d9144f7836ecfe52ac52c6bbcbf12076894707a95bfc22a2dbf801c757ac7ecba421a4fd0696e1bb865d2175d0b567697c14159888 SHA512 3b9f7dcb42290934159a5797a81cad10d02b0e4b5f78378a43845d7feeb7cbf50c5a2bb43ed4dcbf58b86eb437f63cc5b32e64bbea7b4506ba7e7352d24ac8b6
+DIST ebuild-mode-1.83.tar.xz 52476 BLAKE2B 7948c896ead76c410f29b78cfb74e47f221967a52052592c74c54f1ebe295eb191123e45bd8d2675910d0f9c31d3b15af56532ded3f58a725e30b77f960b019b SHA512 fa157b99ffefb27e120804e8f570482411d72755eeb5c91c90afdf30b84fb2c701de6750cc7934a6146ec46727e5ea12f67d59c371a8f514aec28402b05ff73a
diff --git a/app-xemacs/ebuild-mode/ebuild-mode-1.83.ebuild b/app-xemacs/ebuild-mode/ebuild-mode-1.83.ebuild
new file mode 100644
index 0000000000000..7be94c5b43f33
--- /dev/null
+++ b/app-xemacs/ebuild-mode/ebuild-mode-1.83.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/ebuild-mode.git"
+	EGIT_BRANCH="master"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/${PN}"
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="https://distfiles.gentoo.org/pub/proj/emacs/${P}.tar.xz"
+	KEYWORDS="~amd64 ~hppa ~x86"
+fi
+
+DESCRIPTION="Emacs modes for editing ebuilds and other Gentoo specific files"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+
+LICENSE="GPL-2+"
+SLOT="0"
+
+RDEPEND=">=app-editors/xemacs-21.5.35
+	app-xemacs/sh-script
+	app-xemacs/tty-format"
+BDEPEND="${RDEPEND}"
+
+EMACS="${EPREFIX}/usr/bin/xemacs"
+EMACSFLAGS="-batch -q -no-site-file"
+
+src_compile() {
+	${EMACS} ${EMACSFLAGS} \
+		-eval "(add-to-list 'load-path nil)" \
+		-f batch-byte-compile \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+
+	${EMACS} ${EMACSFLAGS} \
+		-eval "(setq autoload-package-name \"${PN}\")" \
+		-eval "(setq generated-autoload-file \"${S}/auto-autoloads.el\")" \
+		-l autoload -f batch-update-autoloads \
+		ebuild-mode.el gentoo-newsitem-mode.el || die
+}
+
+src_test() {
+	emake check EMACS="${EMACS}" EMACSFLAGS="${EMACSFLAGS}"
+}
+
+src_install() {
+	insinto /usr/lib/xemacs/site-packages/lisp/${PN}
+	doins ebuild-mode.{el,elc} ebuild-mode-keywords.el \
+		gentoo-newsitem-mode.{el,elc} ebuild-mode-kw-gen.el \
+		auto-autoloads.el
+}
+
+pkg_postinst() {
+	optfeature "directory support" app-xemacs/dired
+	optfeature "ebuild commands support" sys-apps/portage
+	optfeature "additional development tools" dev-util/pkgdev
+	optfeature "ebuild QA utilities" dev-util/pkgcheck
+}