From bceb4dca620df3495ee94129ffd3f5a277ad9afa Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 28 Jul 2026 07:22:38 +0200
Subject: [PATCH] dev-python/twine: Bump to 7.0.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/twine/Manifest           |  1 +
 dev-python/twine/twine-7.0.0.ebuild | 76 +++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)
 create mode 100644 dev-python/twine/twine-7.0.0.ebuild

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index a0c0e7daea538..2018e3fac6105 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-6.2.0.gh.tar.gz 167087 BLAKE2B 51c95da17fee1336bc94b0847035c0a6e115915696b8a127fb21f8e75c4a8090af221cacd6196279a9352c607a8b643500a6260963f2bc9e6f570b318626d4f6 SHA512 3637b9b6644678a9573ba93d5f2b90b5660f8df126f7a6fde1519fc45f93f1fa0646b16b35087c4b1187b2be1845ce2c3c6f40f96716e2c44d1a6cd471e3b64b
+DIST twine-7.0.0.gh.tar.gz 209937 BLAKE2B e1cba697bc92c574e2113f0223af164def9f7dcabc38d1ac95322f1f7af8a7be232a9d99fce2a65efe7ea7be013f24e7d5f40d07ea1f7df8654b58e464d5a1c7 SHA512 754a1279f074a1dab785ea80922007f36cc81683bbddaad5eea2a13c2449157383830207ed037b1aeef902c39a56ab5223e2773f305d17dd3807eabd9756234b
diff --git a/dev-python/twine/twine-7.0.0.ebuild b/dev-python/twine/twine-7.0.0.ebuild
new file mode 100644
index 0000000000000..8bcd8806b4311
--- /dev/null
+++ b/dev-python/twine/twine-7.0.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	dev-python/id[${PYTHON_USEDEP}]
+	>=dev-python/keyring-21.2.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-26.1[${PYTHON_USEDEP}]
+	>=dev-python/readme-renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-14.3.3[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# Avoid needing heavy virtualx
+		tests/test_auth.py::test_warns_for_empty_password
+	)
+
+	local -x COLUMNS=80
+	epytest
+}